summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAnthony G. Basile <blueness@gentoo.org>2017-08-12 17:55:37 -0400
committerAnthony G. Basile <blueness@gentoo.org>2017-08-12 17:55:37 -0400
commitecbbe957fede6fc29cad915dde6aa6bb0ff8e09f (patch)
tree89f9ac0bf110a3c733daa586b3c9fc47c4124aaf
parentdev-java/javatoolkit: add 9999 ebuild. (diff)
downloadgentoo-ecbbe957fede6fc29cad915dde6aa6bb0ff8e09f.zip
gentoo-ecbbe957fede6fc29cad915dde6aa6bb0ff8e09f.tar.gz
gentoo-ecbbe957fede6fc29cad915dde6aa6bb0ff8e09f.tar.bz2
dev-libs/xmlsec: add libressl support
Package-Manager: Portage-2.3.6, Repoman-2.3.1
-rw-r--r--dev-libs/xmlsec/xmlsec-1.2.24-r1.ebuild65
1 files changed, 65 insertions, 0 deletions
diff --git a/dev-libs/xmlsec/xmlsec-1.2.24-r1.ebuild b/dev-libs/xmlsec/xmlsec-1.2.24-r1.ebuild
new file mode 100644
index 00000000..831e68a
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.24-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="http://www.aleksey.com/xmlsec"
+SRC_URI="http://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls libressl nss +openssl static-libs"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+ gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4
+ >=dev-libs/libxslt-1.0.20
+ gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0 )
+ gnutls? ( >=net-libs/gnutls-2.8.0 )
+ nss? (
+ >=dev-libs/nspr-4.4.1
+ >=dev-libs/nss-3.9
+ )
+ openssl? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}1-${PV}
+
+src_prepare() {
+ default
+ # conditionally install extra documentation
+ if ! use doc ; then
+ sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
+ eautoreconf
+ fi
+}
+
+src_configure() {
+ econf \
+ --enable-pkgconfig \
+ --with-html-dir=/usr/share/doc/${PF}/html \
+ $(use_enable static-libs static) \
+ $(use_with gcrypt gcrypt "") \
+ $(use_with gnutls gnutls "") \
+ $(use_with nss nspr "") \
+ $(use_with nss nss "") \
+ $(use_with openssl openssl "") \
+ $(use_enable openssl aes)
+}
+
+src_test() {
+ emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+ default
+ prune_libtool_files --all
+}