summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2019-06-10 04:49:02 +0200
committerMichał Górny <mgorny@gentoo.org>2019-06-10 04:51:29 +0200
commitf6d2be9fa615d406f21a12e8ecf7c001445a7ee9 (patch)
treef7341d6dc885306a1c0d4fbf91275499c48dcc89
parentapp-admin/consul-replicate: fix tests bug 687646 (diff)
downloadgentoo-f6d2be9fa615d406f21a12e8ecf7c001445a7ee9.tar.gz
gentoo-f6d2be9fa615d406f21a12e8ecf7c001445a7ee9.tar.bz2
gentoo-f6d2be9fa615d406f21a12e8ecf7c001445a7ee9.zip
net-wireless/blueman: Bump to 2.1
Signed-off-by: Michał Górny <mgorny@gentoo.org>
-rw-r--r--net-wireless/blueman/Manifest1
-rw-r--r--net-wireless/blueman/blueman-2.1.ebuild123
2 files changed, 124 insertions, 0 deletions
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index d4627193682..45b65db21b6 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1 +1,2 @@
DIST blueman-2.1.beta1.tar.xz 948440 BLAKE2B da1c6935b47b498d8fa2681c9672381bb6242f8fd752f28d2f2874dd4b602927044db1a291246dfd4c0931d934cc32b2516680cb963fec948fa9452d08d69671 SHA512 c7f04f6d65c9228660efc6e4d2e417eef8dd08f1f703a16270fc883f40be2b7d8f1d7e8728f3a0523b854bfef7fed18b58eb8cdae697d9890a76c220ee2b818b
+DIST blueman-2.1.tar.xz 950124 BLAKE2B e357d8b56e7fa20a03b401585c0bd9680e5138363ec9894c4aaa51c3082fa83f0d2c6ae2f4911c1fab23aa0eab30bd070ec4b97abf997a0cf55365d26f1b7782 SHA512 b675b9edc4fbf4c27f48d3e59bafbe555e59d6d21f7f9358fdd5741b1c7584490010cc5f53f812a7640f0c45aaa29ec4a946548b2a33dfddd7dcad4cce54400c
diff --git a/net-wireless/blueman/blueman-2.1.ebuild b/net-wireless/blueman/blueman-2.1.ebuild
new file mode 100644
index 00000000000..6f86023ac9c
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+inherit gnome2-utils linux-info python-single-r1 systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+ KEYWORDS=""
+else
+ SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+ KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+DEPEND="
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ >=net-wireless/bluez-5:=
+ ${PYTHON_DEPS}"
+BDEPEND="
+ dev-python/cython[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${DEPEND}
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ appindicator? ( dev-libs/libappindicator:3[introspection] )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8
+ )
+ )
+ policykit? ( sys-auth/polkit )
+ pulseaudio? ( media-sound/pulseaudio[bluetooth] )
+ !net-wireless/gnome-bluetooth
+"
+
+S=${WORKDIR}/${P/_/.}
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+ ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+ check_extra_config
+ fi
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ --docdir=/usr/share/doc/${PF}
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+ $(use_enable appindicator)
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}