summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatthew S. Turnbull <sparky@bluefang-logic.com>2021-01-25 01:03:07 -0500
committerJoonas Niilola <juippis@gentoo.org>2021-03-01 15:02:43 +0200
commit265cdd847717520d14fe94e5798ca64c9fff23b3 (patch)
treeb3ca4571e29f6b50be2695a27ca7b26c690c097e /app-accessibility/caribou/caribou-0.4.21-r3.ebuild
parentsys-kernel/gentoo-kernel-bin: Fix versions of genpatches (diff)
downloadgentoo-265cdd847717520d14fe94e5798ca64c9fff23b3.tar.gz
gentoo-265cdd847717520d14fe94e5798ca64c9fff23b3.tar.bz2
gentoo-265cdd847717520d14fe94e5798ca64c9fff23b3.zip
app-accessibility/caribou: Package clean-up
* Update to EAPI7. * Convert to python-single-r1, as it doesn't look like it actually installs python bindings. Also remove env setup handling from launcher scripts. * Drop GTK-2 support. Closes: https://bugs.gentoo.org/629108 Closes: https://bugs.gentoo.org/642582 Bug: https://bugs.gentoo.org/772950 Package-Manager: Portage-3.0.13, Repoman-3.0.2 Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com> Signed-off-by: Joonas Niilola <juippis@gentoo.org>
Diffstat (limited to 'app-accessibility/caribou/caribou-0.4.21-r3.ebuild')
-rw-r--r--app-accessibility/caribou/caribou-0.4.21-r3.ebuild96
1 files changed, 96 insertions, 0 deletions
diff --git a/app-accessibility/caribou/caribou-0.4.21-r3.ebuild b/app-accessibility/caribou/caribou-0.4.21-r3.ebuild
new file mode 100644
index 00000000000..d5ff2747cb3
--- /dev/null
+++ b/app-accessibility/caribou/caribou-0.4.21-r3.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome.org gnome2-utils python-single-r1 vala
+
+DESCRIPTION="Input assistive technology intended for switch and pointer users"
+HOMEPAGE="https://wiki.gnome.org/Projects/Caribou"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ app-accessibility/at-spi2-core
+ $(python_gen_cond_dep '
+ >=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
+ ')
+ >=dev-libs/gobject-introspection-0.10.7:=
+ dev-libs/libgee:0.8
+ dev-libs/libxml2
+ >=media-libs/clutter-1.5.11:1.0[introspection]
+ >=x11-libs/gtk+-3:3[introspection]
+ x11-libs/libX11
+ x11-libs/libxklavier
+ x11-libs/libXtst
+"
+# gsettings-desktop-schemas is needed for the 'toolkit-accessibility' key
+# pyatspi-2.1.90 needed to run caribou if pygobject:3 is installed
+# librsvg needed to load svg images in css styles
+RDEPEND="
+ ${COMMON_DEPEND}
+ dev-libs/glib[dbus]
+ $(python_gen_cond_dep '
+ >=dev-python/pyatspi-2.1.90[${PYTHON_USEDEP}]
+ ')
+ >=gnome-base/gsettings-desktop-schemas-3
+ gnome-base/librsvg:2
+ sys-apps/dbus
+ !<x11-base/xorg-server-1.20.10
+"
+DEPEND="
+ ${COMMON_DEPEND}
+ dev-libs/libxslt
+"
+BDEPEND="
+ $(vala_depend)
+ >=dev-util/intltool-0.35.5
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-fix-compilation-error.patch"
+ "${FILESDIR}/${PN}-fix-subkey-popmenu.patch"
+ "${FILESDIR}/${PN}-fix-xadapter-xkb-calls.patch"
+ "${FILESDIR}/${PN}-fix-antler-style-css.patch"
+ "${FILESDIR}/${PN}-fix-python-env.patch"
+)
+
+src_prepare() {
+ default
+ vala_src_prepare
+ gnome2_disable_deprecation_warning
+}
+
+src_configure() {
+ econf \
+ --disable-maintainer-mode \
+ --disable-schemas-compile \
+ --disable-docs \
+ --disable-static \
+ --disable-gtk2-module \
+ --enable-gtk3-module
+}
+
+src_install() {
+ DOCS="AUTHORS NEWS README"
+ default
+ find "${D}" -name '*.la' -delete || die
+ python_optimize
+}
+
+pkg_postinst() {
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ gnome2_schemas_update
+}