summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorGilles Dartiguelongue <eva@gentoo.org>2016-11-01 14:34:19 +0100
committerGilles Dartiguelongue <eva@gentoo.org>2016-11-01 18:06:11 +0100
commit0068693e84bbe8ae7994bca2a2cb6bf4200e0534 (patch)
tree740a5322025b464a57978dd0839edc6a0c06f158 /app-accessibility/orca/orca-3.22.1.ebuild
parentmedia-libs/mesa: Drop 13.0.0 RCs. (diff)
downloadgentoo-0068693e84bbe8ae7994bca2a2cb6bf4200e0534.tar.gz
gentoo-0068693e84bbe8ae7994bca2a2cb6bf4200e0534.tar.bz2
gentoo-0068693e84bbe8ae7994bca2a2cb6bf4200e0534.zip
app-accessibility/orca: version bump 3.20.3-r1 → 3.22.1
Package-Manager: portage-2.3.2
Diffstat (limited to 'app-accessibility/orca/orca-3.22.1.ebuild')
-rw-r--r--app-accessibility/orca/orca-3.22.1.ebuild73
1 files changed, 73 insertions, 0 deletions
diff --git a/app-accessibility/orca/orca-3.22.1.ebuild b/app-accessibility/orca/orca-3.22.1.ebuild
new file mode 100644
index 00000000000..ce568b8ec4e
--- /dev/null
+++ b/app-accessibility/orca/orca-3.22.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{3,4,5} )
+PYTHON_REQ_USE="threads"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+ >=app-accessibility/at-spi2-atk-2.12:2
+ >=app-accessibility/at-spi2-core-2.12:2[introspection]
+ >=dev-libs/atk-2.10
+ >=dev-libs/glib-2.28:2
+ dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+ >=dev-python/pygobject-3.10:3[${PYTHON_USEDEP}]
+ media-libs/gstreamer:1.0[introspection]
+ >=x11-libs/gtk+-3.6.2:3[introspection]
+ braille? (
+ >=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+ dev-libs/liblouis[python,${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+ >=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+ dev-libs/atk[introspection]
+ dev-python/pyatspi[${PYTHON_USEDEP}]
+ dev-python/setproctitle[${PYTHON_USEDEP}]
+ x11-libs/libwnck:3[introspection]
+ x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-util/intltool-0.50
+ dev-util/itstool
+ virtual/pkgconfig
+"
+# app-text/yelp-tools
+
+src_prepare() {
+ gnome2_src_prepare
+ python_copy_sources
+}
+
+src_configure() {
+ python_foreach_impl run_in_build_dir gnome2_src_configure \
+ $(use_with braille liblouis)
+}
+
+src_compile() {
+ python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+ installing() {
+ gnome2_src_install
+ # Massage shebang to make python_doscript happy
+ sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
+ -i src/orca/orca || die
+ python_doscript src/orca/orca
+ }
+ python_foreach_impl run_in_build_dir installing
+}