summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2020-06-29 16:26:45 +0200
committerLars Wendler <polynomial-c@gentoo.org>2020-06-29 16:26:45 +0200
commit878436e264d856317f7ba79832be8ca9e9d3b242 (patch)
tree0c74991348847926a569eaf03e428b6825a7d2f3 /app-arch/unrar/unrar-5.9.4.ebuild
parentnet-misc/kea: Removed old (diff)
downloadgentoo-878436e264d856317f7ba79832be8ca9e9d3b242.tar.gz
gentoo-878436e264d856317f7ba79832be8ca9e9d3b242.tar.bz2
gentoo-878436e264d856317f7ba79832be8ca9e9d3b242.zip
app-arch/unrar: Bump to version 5.9.4
Package-Manager: Portage-2.3.103, Repoman-2.3.23 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'app-arch/unrar/unrar-5.9.4.ebuild')
-rw-r--r--app-arch/unrar/unrar-5.9.4.ebuild70
1 files changed, 70 insertions, 0 deletions
diff --git a/app-arch/unrar/unrar-5.9.4.ebuild b/app-arch/unrar/unrar-5.9.4.ebuild
new file mode 100644
index 00000000000..7a4b90b3f3b
--- /dev/null
+++ b/app-arch/unrar/unrar-5.9.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic multilib toolchain-funcs
+
+MY_PN="${PN}src"
+
+DESCRIPTION="Uncompress rar files"
+HOMEPAGE="https://www.rarlab.com/rar_add.htm"
+SRC_URI="https://www.rarlab.com/rar/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="unRAR"
+# subslot = soname version
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="!<=app-arch/unrar-gpl-0.0.1_p20080417"
+
+S="${WORKDIR}/unrar"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-5.9.3-build.patch
+ "${FILESDIR}"/${PN}-5.5.5-honor-flags.patch
+)
+
+src_prepare() {
+ default
+
+ local sed_args=( -e "/libunrar/s:.so:$(get_libname ${PV%.*.*}):" )
+ if [[ ${CHOST} == *-darwin* ]] ; then
+ sed_args+=( -e "s:-shared:-dynamiclib -install_name ${EPREFIX}/usr/$(get_libdir)/libunrar$(get_libname ${PV%.*.*}):" )
+ else
+ sed_args+=( -e "s:-shared:& -Wl,-soname -Wl,libunrar$(get_libname ${PV%.*.*}):" )
+ fi
+ sed -i "${sed_args[@]}" makefile || die
+}
+
+src_configure() {
+ mkdir -p build-{lib,bin}
+ printf 'VPATH = ..\ninclude ../makefile' > build-lib/Makefile || die
+ cp build-{lib,bin}/Makefile || die
+}
+
+src_compile() {
+ unrar_make() {
+ emake AR="$(tc-getAR)" CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}" STRIP=true "$@"
+ }
+
+ unrar_make CXXFLAGS+=" -fPIC" -C build-lib lib
+ ln -s libunrar$(get_libname ${PV%.*.*}) build-lib/libunrar$(get_libname) || die
+ ln -s libunrar$(get_libname ${PV%.*.*}) build-lib/libunrar$(get_libname ${PV}) || die
+
+ unrar_make -C build-bin
+}
+
+src_install() {
+ dobin build-bin/unrar
+ dodoc readme.txt
+
+ dolib.so build-lib/libunrar*
+
+ insinto /usr/include/libunrar${PV%.*.*}
+ doins *.hpp
+ dosym libunrar${PV%.*.*} /usr/include/libunrar
+
+ find "${ED}" -type f -name "*.a" -delete || die
+}