summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorGöktürk Yüksek <gokturk@gentoo.org>2021-08-09 20:12:10 -0400
committerGöktürk Yüksek <gokturk@gentoo.org>2021-08-09 20:21:02 -0400
commit42691aa3df83ac90411d106253a571b939279c38 (patch)
tree4d748037e73e18cafaa95165fe41347390ed89dc /app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild
parentsci-geosciences/gpsd: keyword 3.21 for ~riscv (diff)
downloadgentoo-42691aa3df83ac90411d106253a571b939279c38.tar.gz
gentoo-42691aa3df83ac90411d106253a571b939279c38.tar.bz2
gentoo-42691aa3df83ac90411d106253a571b939279c38.zip
app-crypt/libu2f-server: bump to EAPI 7
Package-Manager: Portage-3.0.20, Repoman-3.0.3 Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>
Diffstat (limited to 'app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild')
-rw-r--r--app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild b/app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild
new file mode 100644
index 00000000000..c4164b37658
--- /dev/null
+++ b/app-crypt/libu2f-server/libu2f-server-1.1.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Yubico Universal 2nd Factor (U2F) server C Library"
+HOMEPAGE="https://developers.yubico.com/libu2f-server/"
+SRC_URI="https://developers.yubico.com/${PN}/Releases/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0/0.1"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-libs/openssl:0=[${MULTILIB_USEDEP}]
+ dev-libs/hidapi[${MULTILIB_USEDEP}]
+ dev-libs/json-c:=[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+ test? ( dev-libs/check[${MULTILIB_USEDEP}] )
+"
+BDEPEND="
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-1.1.0-disable-help2man-gengetopt-checks.patch"
+ "${FILESDIR}/${PN}-1.1.0-jsonc014.patch"
+)
+
+src_prepare() {
+ default
+ eautoreconf
+ touch man/u2f-server.1 || die # do not rebuild the man page
+}
+
+multilib_src_configure() {
+ myeconfargs=(
+ --disable-h2a # tarball already contains the manpage
+ $(use_enable static-libs static)
+ $(use_enable test tests)
+ )
+
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+ default
+ find "${D}" -name '*.la' -delete || die
+}