proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 58 insertions, 0 deletions

diff --git a/app-crypt/monkeysphere/monkeysphere-0.36-r1.ebuild b/app-crypt/monkeysphere/monkeysphere-0.36-r1.ebuild
new file mode 100644
index 000000000000..962b46e6c56e
--- /dev/null
+++ b/app-crypt/monkeysphere/monkeysphere-0.36-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils user
+
+DESCRIPTION="Leverage the OpenPGP web of trust for OpenSSH and Web authentication"
+HOMEPAGE="http://web.monkeysphere.info/"
+SRC_URI="http://archive.${PN}.info/debian/pool/${PN}/${PN::1}/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+# Tests do weird things with network and fail OOTB.
+RESTRICT="test"
+
+RDEPEND="
+	app-crypt/gnupg
+	app-misc/lockfile-progs
+	dev-perl/Crypt-OpenSSL-RSA
+	dev-perl/Digest-SHA1
+	|| ( net-analyzer/netcat net-misc/socat )"
+DEPEND="${RDEPEND}
+	test? ( net-misc/socat )"
+
+pkg_setup()
+{
+	einfo "Creating named group and user"
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+}
+
+src_prepare()
+{
+	epatch "${FILESDIR}/${P}_default_shell.patch" \
+		"${FILESDIR}/${P}_non_default_port.patch" \
+		"${FILESDIR}/${P}_userid_empty_line.patch"
+
+	sed -i "s#share/doc/${PN}#share/doc/${PF}#" Makefile || die
+}
+
+src_install()
+{
+	default
+
+	dodir /var/lib/${PN}
+	fowners root:${PN} /var/lib/${PN}
+	fperms 751 /var/lib/${PN}
+}
+
+pkg_postinst()
+{
+	${PN}-authentication setup || die
+}