summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorZac Medico <zmedico@gentoo.org>2019-09-13 10:06:16 -0700
committerZac Medico <zmedico@gentoo.org>2019-09-13 10:06:16 -0700
commit715188dc3d8b7ceaef29b5ec0c7cfbd870d9b67f (patch)
treec3bb3e5d95c3d06d46bac2ce43a004b91da38da2 /app-emulation/buildah/buildah-1.11.2.ebuild
parentnet-fs/minio: Version bump (diff)
downloadgentoo-715188dc3d8b7ceaef29b5ec0c7cfbd870d9b67f.tar.gz
gentoo-715188dc3d8b7ceaef29b5ec0c7cfbd870d9b67f.tar.bz2
gentoo-715188dc3d8b7ceaef29b5ec0c7cfbd870d9b67f.zip
app-emulation/buildah: Bump to version 1.11.2
Package-Manager: Portage-2.3.76, Repoman-2.3.17 Signed-off-by: Zac Medico <zmedico@gentoo.org>
Diffstat (limited to 'app-emulation/buildah/buildah-1.11.2.ebuild')
-rw-r--r--app-emulation/buildah/buildah-1.11.2.ebuild57
1 files changed, 57 insertions, 0 deletions
diff --git a/app-emulation/buildah/buildah-1.11.2.ebuild b/app-emulation/buildah/buildah-1.11.2.ebuild
new file mode 100644
index 00000000000..8962d91ae9c
--- /dev/null
+++ b/app-emulation/buildah/buildah-1.11.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit bash-completion-r1 golang-vcs-snapshot
+
+KEYWORDS="~amd64"
+DESCRIPTION="A tool that facilitates building OCI images"
+HOMEPAGE="https://github.com/containers/buildah"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="ostree selinux"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+GIT_COMMIT="0bafbfe"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="app-crypt/gpgme:=
+ app-emulation/skopeo
+ dev-libs/libgpg-error:=
+ dev-libs/libassuan:=
+ sys-fs/lvm2:=
+ sys-libs/libseccomp:=
+ selinux? ( sys-libs/libselinux:= )"
+DEPEND="${RDEPEND}"
+RESTRICT="test"
+REQUIRED_USE="!selinux? ( !ostree )"
+S="${WORKDIR}/${P}/src/${EGO_PN}"
+
+src_prepare() {
+ default
+ sed -e 's|^\(GIT_COMMIT ?= \).*|\1'${GIT_COMMIT}'|' -i Makefile || die
+
+ [[ -f ostree_tag.sh ]] || die
+ use ostree || { echo -e "#!/bin/sh\necho containers_image_ostree_stub" > \
+ ostree_tag.sh || die; }
+
+ [[ -f selinux_tag.sh ]] || die
+ use selinux || { echo -e "#!/bin/sh\ntrue" > \
+ selinux_tag.sh || die; }
+}
+
+src_compile() {
+ export -n GOCACHE XDG_CACHE_HOME
+ GOPATH="${WORKDIR}/${P}" emake all
+}
+
+src_install() {
+ dodoc CHANGELOG.md CONTRIBUTING.md README.md install.md troubleshooting.md
+ doman docs/*.1
+ dodoc -r docs/tutorials
+ dobin ${PN} imgtype
+ dobashcomp contrib/completions/bash/buildah
+}
+
+src_test() {
+ GOPATH="${WORKDIR}/${P}" emake test-unit
+}