summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2020-04-13 11:48:38 +0100
committerSergei Trofimovich <slyfox@gentoo.org>2020-04-13 11:49:29 +0100
commit29577ded45b741d4233b837a6542b551c5f14f23 (patch)
tree9db9740e7b6591c6bb38a0ee543bea7acc0e836d /app-misc/pax-utils/pax-utils-1.2.6.ebuild
parentapp-portage/nattka: Bump to 0.1.6 (diff)
downloadgentoo-29577ded45b741d4233b837a6542b551c5f14f23.tar.gz
gentoo-29577ded45b741d4233b837a6542b551c5f14f23.tar.bz2
gentoo-29577ded45b741d4233b837a6542b551c5f14f23.zip
app-misc/pax-utils: bump up to 1.2.6
A few new changes: Göktürk Yüksek (1): Add RISC-V to the list of architectures in ELF Manoj Gupta (1): lddtree: Put ldso interpreter library path at end Mike Frysinger (2): pylintrc: enable more warnings pylint: load python via $PATH Sergei Trofimovich (3): scanelf.c: don't srash in -v mode on non-functions scanelf.c: be more verbose at saying what all the addresses mean security.c: allow 'statx' in seccomp sandbox (musl-1.1.24) Closes: https://bugs.gentoo.org/717300 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Diffstat (limited to 'app-misc/pax-utils/pax-utils-1.2.6.ebuild')
-rw-r--r--app-misc/pax-utils/pax-utils-1.2.6.ebuild72
1 files changed, 72 insertions, 0 deletions
diff --git a/app-misc/pax-utils/pax-utils-1.2.6.ebuild b/app-misc/pax-utils/pax-utils-1.2.6.ebuild
new file mode 100644
index 00000000000..d39090d1af7
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.2.6.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit eutils python-single-r1 toolchain-funcs unpacker
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+ https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+ python? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/pyelftools[${PYTHON_MULTI_USEDEP}]
+ ')
+ )
+ seccomp? ( sys-libs/libseccomp )"
+DEPEND="${RDEPEND}
+ caps? ( virtual/pkgconfig )
+ seccomp? ( virtual/pkgconfig )
+ app-arch/xz-utils"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+ emake \
+ USE_CAP=$(usex caps) \
+ USE_DEBUG=$(usex debug) \
+ USE_PYTHON=$(usex python) \
+ USE_SECCOMP=$(usex seccomp) \
+ "$@"
+}
+
+pkg_setup() {
+ if use python; then
+ python-single-r1_pkg_setup
+ fi
+}
+
+src_configure() {
+ # Avoid slow configure+gnulib+make if on an up-to-date Linux system
+ if use prefix || ! use kernel_linux ||
+ has_version '<sys-libs/glibc-2.10'
+ then
+ econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+ else
+ tc-export CC PKG_CONFIG
+ fi
+}
+
+src_compile() {
+ _emake
+}
+
+src_test() {
+ _emake check
+}
+
+src_install() {
+ _emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+ use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}