app-misc/pax-utils: add 1.3.6

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 93 insertions, 17 deletions

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index f4607328ef6b..f13693d55977 100644
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1 +1,2 @@
 DIST pax-utils-1.3.5.tar.xz 119764 BLAKE2B 13bd4dbdadefb382133bf42a2b1e740e84ac11661595b082346c80ff05fc7423f5d75cc01ff8a651d921310ae66c2b39a862d0b9db5d7f18e11d393360627fcf SHA512 f2b1753e15907461cc395abffe033d7f7ab8eb15e296b874e2c9d00507458672347b32d7f2f05d3a8625fc3afbdbf0721543f84e062afce7181a726d967e4836
+DIST pax-utils-1.3.6.tar.xz 113816 BLAKE2B de33820acc5cbbace2f7e3f831dc1c4d2ead58e1b0418c96ef42694d7f0cc1d49a37764d6f8b60a00aaa25fd3d40ba64fb4cf1798e07b917936704738e6f1042 SHA512 94d6bdcac0109cc7218fc523594100b4bb5877e0709f5443903ae8aca96e8f3f45cf47b28b57ac146caf6713ad7895a6f67adf4364d9a14986c8b7e0399f3865
diff --git a/app-misc/pax-utils/pax-utils-1.3.6.ebuild b/app-misc/pax-utils/pax-utils-1.3.6.ebuild
new file mode 100644
index 000000000000..599c1ab4a187
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.3.6.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Note: if bumping pax-utils because of syscall changes in glibc, please
+# revbump glibc and update the dependency in its ebuild for the affected
+# versions.
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit meson python-single-r1
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pax-utils.git"
+	inherit git-r3
+else
+	SRC_URI="
+		https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}.tar.xz
+		https://dev.gentoo.org/~vapier/dist/${P}.tar.xz
+	"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="caps +man python seccomp test"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( python )
+"
+RESTRICT="!test? ( test )"
+
+MY_PYTHON_DEPS="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pyelftools[${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	caps? ( >=sys-libs/libcap-2.24 )
+	python? ( ${MY_PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	caps? ( virtual/pkgconfig )
+	man? ( app-text/xmlto )
+	python? ( ${MY_PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	if use test || use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		"-Dlddtree_implementation=$(usex python python sh)"
+		$(meson_feature caps use_libcap)
+		$(meson_feature man build_manpages)
+		$(meson_use seccomp use_seccomp)
+		$(meson_use test tests)
+
+		# fuzzing is currently broken
+		-Duse_fuzzing=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}
diff --git a/app-misc/pax-utils/pax-utils-9999.ebuild b/app-misc/pax-utils/pax-utils-9999.ebuild
index 9aae26cb7eaf..599c1ab4a187 100644
--- a/app-misc/pax-utils/pax-utils-9999.ebuild
+++ b/app-misc/pax-utils/pax-utils-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022 Gentoo Authors
+# Copyright 2022-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -17,39 +17,37 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pax-utils.git"
 	inherit git-r3
 else
-	SRC_URI="mirror://gentoo/${P}.tar.xz
-		https://dev.gentoo.org/~sam/distfiles/${P}.tar.xz
-		https://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
+	SRC_URI="
+		https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}.tar.xz
+		https://dev.gentoo.org/~vapier/dist/${P}.tar.xz
+	"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
 IUSE="caps +man python seccomp test"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( python )
+"
+RESTRICT="!test? ( test )"
 
-_PYTHON_DEPS="
+MY_PYTHON_DEPS="
 	${PYTHON_DEPS}
 	$(python_gen_cond_dep '
 		dev-python/pyelftools[${PYTHON_USEDEP}]
 	')
 "
-
-RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
-	python? ( ${_PYTHON_DEPS} )
+RDEPEND="
+	caps? ( >=sys-libs/libcap-2.24 )
+	python? ( ${MY_PYTHON_DEPS} )
 "
 DEPEND="${RDEPEND}"
 BDEPEND="
 	caps? ( virtual/pkgconfig )
 	man? ( app-text/xmlto )
-
-	python? ( ${_PYTHON_DEPS} )
-"
-REQUIRED_USE="
-	python? ( ${PYTHON_REQUIRED_USE} )
-	test? ( python )
-"
-RESTRICT="
-	!test? ( test )
+	python? ( ${MY_PYTHON_DEPS} )
 "
 
 pkg_setup() {