summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2019-08-30 09:18:57 +0200
committerLars Wendler <polynomial-c@gentoo.org>2019-08-30 09:18:57 +0200
commitc0688d87fd51492e11b0c7d54e11e82ee848b1c3 (patch)
tree3d1e8d6254f1c33c57ec3d4126664a9817e4d619 /app-misc/uptimed/uptimed-0.4.2.ebuild
parentx11-wm/icewm: Removed old (diff)
downloadgentoo-c0688d87fd51492e11b0c7d54e11e82ee848b1c3.tar.gz
gentoo-c0688d87fd51492e11b0c7d54e11e82ee848b1c3.tar.bz2
gentoo-c0688d87fd51492e11b0c7d54e11e82ee848b1c3.zip
app-misc/uptimed: Bump to version 0.4.2
Package-Manager: Portage-2.3.73, Repoman-2.3.17 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'app-misc/uptimed/uptimed-0.4.2.ebuild')
-rw-r--r--app-misc/uptimed/uptimed-0.4.2.ebuild61
1 files changed, 61 insertions, 0 deletions
diff --git a/app-misc/uptimed/uptimed-0.4.2.ebuild b/app-misc/uptimed/uptimed-0.4.2.ebuild
new file mode 100644
index 00000000000..1986bbd3429
--- /dev/null
+++ b/app-misc/uptimed/uptimed-0.4.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="System uptime record daemon that keeps track of your highest uptimes"
+HOMEPAGE="https://github.com/rpodgorny/uptimed/"
+SRC_URI="https://github.com/rpodgorny/uptimed/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="static-libs"
+
+RDEPEND="
+ acct-group/uptimed
+ acct-user/uptimed
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+ default
+ # fix configure.ac for >=automake-1.13 (bug #467582)
+ sed 's@AM_CONFIG_HEADER@AC_CONFIG_HEADERS@' -i configure.ac || die
+ eautoreconf
+}
+
+src_configure() {
+ econf $(use_enable static-libs static)
+}
+
+src_install() {
+ local DOCS=( ChangeLog README.md TODO AUTHORS CREDITS INSTALL.cgi sample-cgi/* )
+ default
+ find "${ED}" -type f -name '*.la' -delete || die
+
+ local spooldir="/var/spool/${PN}"
+ keepdir ${spooldir}
+ fowners uptimed:uptimed ${spooldir}
+
+ newinitd "${FILESDIR}"/${PN}.init-r1 uptimed
+ systemd_dounit "${FILESDIR}/${PN}.service"
+}
+
+pkg_postinst() {
+ local spooldir="/var/spool/${PN}"
+ if [[ -d "${spooldir}" ]] ; then
+ einfo "Fixing permissions in ${spooldir}"
+ find ${spooldir} -type f -links 1 \
+ \( -name records -o -name records.old \) \
+ | xargs --no-run-if-empty chown uptimed:uptimed || die
+ fi
+ echo
+ elog "Start uptimed with '/etc/init.d/uptimed start' (for openRC)"
+ elog "or systemctl start uptimed (for systemd)"
+ elog "To view your uptime records, use the command 'uprecords'."
+ echo
+}