app-office/gnumeric: bump to 1.12.39

There's also a 1.12.40 released, but that needs more care for new
python introspection overrides installing; configure.ac changes are
no good out of the box for sandbox distro building (and potentially
multiple python versions in the future, albeit python2 only for
now it seems).

Package-Manager: Portage-2.3.28, Repoman-2.3.9

1 files changed, 64 insertions, 0 deletions

diff --git a/app-office/gnumeric/gnumeric-1.12.39.ebuild b/app-office/gnumeric/gnumeric-1.12.39.ebuild
new file mode 100644
index 000000000000..4c5b03f89eb7
--- /dev/null
+++ b/app-office/gnumeric/gnumeric-1.12.39.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 flag-o-matic python-single-r1
+
+DESCRIPTION="The GNOME Spreadsheet"
+HOMEPAGE="http://www.gnumeric.org/"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="+introspection libgda perl python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Missing gnome-extra/libgnomedb required version in tree
+# but its upstream is dead and will be dropped soon.
+
+# lots of missing files, also fails tests due to 80-bit long story
+# upstream bug #721556
+RESTRICT="test"
+
+RDEPEND="
+	app-arch/bzip2
+	sys-libs/zlib
+	>=dev-libs/glib-2.38.0:2
+	>=gnome-extra/libgsf-1.14.33:=
+	>=x11-libs/goffice-0.10.38:0.10
+	>=dev-libs/libxml2-2.4.12:2
+	>=x11-libs/pango-1.24.0:=
+
+	>=x11-libs/gtk+-3.8.7:3
+	x11-libs/cairo:=[svg]
+
+	introspection? ( >=dev-libs/gobject-introspection-1:= )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-3:3[${PYTHON_USEDEP}] )
+	libgda? ( gnome-extra/libgda:5[gtk] )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.0
+	app-text/yelp-tools
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--with-zlib \
+		$(use_with libgda gda) \
+		$(use_enable introspection) \
+		$(use_with perl) \
+		$(use_with python)
+}