summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2020-03-12 09:54:11 -0700
committerMatt Turner <mattst88@gentoo.org>2020-03-12 09:55:31 -0700
commit33a19d76c9363657630d3cf048e649b8276897c4 (patch)
tree2a1b0aa6816b1acd94ad58479237eab7457a1639 /app-portage/gentoolkit/gentoolkit-0.4.8.ebuild
parentsys-libs/glibc: Revision bump with new patchset 6 (diff)
downloadgentoo-33a19d76c9363657630d3cf048e649b8276897c4.tar.gz
gentoo-33a19d76c9363657630d3cf048e649b8276897c4.tar.bz2
gentoo-33a19d76c9363657630d3cf048e649b8276897c4.zip
app-portage/gentoolkit: Version bump to 0.4.8
Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'app-portage/gentoolkit/gentoolkit-0.4.8.ebuild')
-rw-r--r--app-portage/gentoolkit/gentoolkit-0.4.8.ebuild75
1 files changed, 75 insertions, 0 deletions
diff --git a/app-portage/gentoolkit/gentoolkit-0.4.8.ebuild b/app-portage/gentoolkit/gentoolkit-0.4.8.ebuild
new file mode 100644
index 00000000000..e4162f13322
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.4.8.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage-Tools"
+SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+ sys-apps/portage[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+ sys-apps/gawk
+ sys-apps/gentoo-functions"
+
+python_prepare_all() {
+ python_setup
+ echo VERSION="${PVR}" "${PYTHON}" setup.py set_version
+ VERSION="${PVR}" "${PYTHON}" setup.py set_version
+ distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+}
+
+pkg_preinst() {
+ if has_version "<${CATEGORY}/${PN}-0.4.0"; then
+ SHOW_GENTOOKIT_DEV_DEPRECATED_MSG=1
+ fi
+}
+
+pkg_postinst() {
+ # Create cache directory for revdep-rebuild
+ mkdir -p -m 0755 "${EROOT}"/var/cache
+ mkdir -p -m 0700 "${EROOT}"/var/cache/revdep-rebuild
+
+ if [[ ${SHOW_GENTOOKIT_DEV_DEPRECATED_MSG} ]]; then
+ elog "Starting with version 0.4.0, ebump, ekeyword and imlate are now"
+ elog "part of the gentoolkit package."
+ elog "The gentoolkit-dev package is now deprecated in favor of a single"
+ elog "gentoolkit package. The remaining tools from gentoolkit-dev"
+ elog "are now obsolete/unused with the git based tree."
+ fi
+
+ # Only show the elog information on a new install
+ if [[ ! ${REPLACING_VERSIONS} ]]; then
+ elog
+ elog "For further information on gentoolkit, please read the gentoolkit"
+ elog "guide: https://wiki.gentoo.org/wiki/Gentoolkit"
+ elog
+ elog "Another alternative to equery is app-portage/portage-utils"
+ elog
+ elog "Additional tools that may be of interest:"
+ elog
+ elog " app-admin/eclean-kernel"
+ elog " app-portage/diffmask"
+ elog " app-portage/flaggie"
+ elog " app-portage/install-mask"
+ elog " app-portage/portpeek"
+ elog " app-portage/smart-live-rebuild"
+ fi
+}