summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2018-12-30 20:33:51 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2018-12-30 21:07:25 +0100
commitf778766c0afe2e4ef26d33cb033ebe1410cde605 (patch)
treefc8ad9de02db2556b0ee0a84558590e86acdbd7d /app-text
parentdev-cpp/libcmis: 0.5.2 version bump (diff)
downloadgentoo-f778766c0afe2e4ef26d33cb033ebe1410cde605.tar.gz
gentoo-f778766c0afe2e4ef26d33cb033ebe1410cde605.tar.bz2
gentoo-f778766c0afe2e4ef26d33cb033ebe1410cde605.zip
app-text/libetonyek: 0.1.9 version bump
Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'app-text')
-rw-r--r--app-text/libetonyek/Manifest1
-rw-r--r--app-text/libetonyek/libetonyek-0.1.9.ebuild61
-rw-r--r--app-text/libetonyek/libetonyek-9999.ebuild15
3 files changed, 70 insertions, 7 deletions
diff --git a/app-text/libetonyek/Manifest b/app-text/libetonyek/Manifest
index 974952711fa..7a9f758407e 100644
--- a/app-text/libetonyek/Manifest
+++ b/app-text/libetonyek/Manifest
@@ -1 +1,2 @@
DIST libetonyek-0.1.8.tar.xz 1324868 BLAKE2B 2088349df75011f54f5822ffd69336a7942a148ff829111c02efbfb99c705a9e00105147942f3e9e81278be3b1f2be4d63aba8cbf6a54127f04fc547df6b7b1d SHA512 c8c08100b0c75e0420bbcd796f7cb9285e77ce1be34757df5b237d114a428a4a6094f12e442f81769a2fac5be45ea4376ff9e1d90448e18b3443bfe7c645a865
+DIST libetonyek-0.1.9.tar.xz 1477064 BLAKE2B 088d27c83d4aff41cb208cf840def78e323f378a1b7d456448db3abf51d1e850c8159ace75c8836958b533c2b84e583d5a622e638081230d2f862f6d1d175e98 SHA512 3f439b369d450bb1a4bdb3fe92023bda234b323cf676570f1738318c56867a97910f536280b9b164c3fdaa423a3ee669c935df75a5c700bc1530ea5b9a00391e
diff --git a/app-text/libetonyek/libetonyek-0.1.9.ebuild b/app-text/libetonyek/libetonyek-0.1.9.ebuild
new file mode 100644
index 00000000000..a59ca6e0096
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+ inherit autotools git-r3
+else
+ SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc static-libs test"
+
+RDEPEND="
+ app-text/liblangtag
+ dev-libs/librevenge
+ dev-libs/libxml2
+ >=dev-util/mdds-1.3.1:1=
+ sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+ dev-libs/boost
+ media-libs/glm
+ sys-devel/libtool
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+ test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+ default
+ [[ -d m4 ]] || mkdir "m4"
+ [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --disable-werror
+ $(use_with doc docs)
+ $(use_enable static-libs static)
+ $(use_enable test tests)
+ )
+ if has_version ">=dev-util/mdds-1.4"; then
+ myeconfargs+=( --with-mdds=1.4 )
+ else
+ myeconfargs+=( --with-mdds=1.2 )
+ fi
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ default
+ find "${D}" -name '*.la' -delete || die
+}
diff --git a/app-text/libetonyek/libetonyek-9999.ebuild b/app-text/libetonyek/libetonyek-9999.ebuild
index 434fddd7f1a..a59ca6e0096 100644
--- a/app-text/libetonyek/libetonyek-9999.ebuild
+++ b/app-text/libetonyek/libetonyek-9999.ebuild
@@ -3,28 +3,29 @@
EAPI=7
-EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
-[[ ${PV} == 9999 ]] && inherit autotools git-r3
-
+if [[ ${PV} = 9999 ]]; then
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+ inherit autotools git-r3
+else
+ SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
DESCRIPTION="Library parsing Apple Keynote presentations"
HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
-[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="doc static-libs test"
RDEPEND="
app-text/liblangtag
dev-libs/librevenge
dev-libs/libxml2
+ >=dev-util/mdds-1.3.1:1=
sys-libs/zlib
"
DEPEND="${RDEPEND}
dev-libs/boost
- >=dev-util/mdds-1.4.2:1=
media-libs/glm
sys-devel/libtool
virtual/pkgconfig