summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMatt Turner <mattst88@gentoo.org>2021-05-21 18:46:15 -0700
committerMatt Turner <mattst88@gentoo.org>2021-05-21 18:47:09 -0700
commit02769da3516a6daf96231a7a3aa0664fb1eda5ac (patch)
treea33377a43aee03c01dc22bf294d51cdc7b8b6c7d /dev-cpp/glibmm/glibmm-2.66.1.ebuild
parentmedia-libs/exiftool: add 12.26 (diff)
downloadgentoo-02769da3516a6daf96231a7a3aa0664fb1eda5ac.tar.gz
gentoo-02769da3516a6daf96231a7a3aa0664fb1eda5ac.tar.bz2
gentoo-02769da3516a6daf96231a7a3aa0664fb1eda5ac.zip
dev-cpp/glibmm: Version bump to 2.66.1
Signed-off-by: Matt Turner <mattst88@gentoo.org>
Diffstat (limited to 'dev-cpp/glibmm/glibmm-2.66.1.ebuild')
-rw-r--r--dev-cpp/glibmm/glibmm-2.66.1.ebuild66
1 files changed, 66 insertions, 0 deletions
diff --git a/dev-cpp/glibmm/glibmm-2.66.1.ebuild b/dev-cpp/glibmm/glibmm-2.66.1.ebuild
new file mode 100644
index 00000000000..27244f110de
--- /dev/null
+++ b/dev-cpp/glibmm/glibmm-2.66.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+inherit gnome.org meson multilib-minimal python-any-r1
+
+DESCRIPTION="C++ interface for glib2"
+HOMEPAGE="https://www.gtkmm.org"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+IUSE="doc debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-libs/libsigc++-2.9.1:2[${MULTILIB_USEDEP}]
+ >=dev-libs/glib-2.61.2:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ ${PYTHON_DEPS}
+ virtual/pkgconfig
+ doc? (
+ app-doc/doxygen[dot]
+ dev-lang/perl
+ dev-perl/XML-Parser
+ dev-libs/libxslt
+ media-gfx/graphviz
+ )
+"
+
+src_prepare() {
+ default
+
+ # giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
+ sed -i -e '/giomm_tls_client/d' tests/meson.build || die
+
+ if ! use test; then
+ sed -i -e "/^subdir('tests')/d" meson.build || die
+ fi
+}
+
+multilib_src_configure() {
+ local emesonargs=(
+ -Dwarnings=min
+ -Dbuild-deprecated-api=true
+ -Dbuild-documentation=$(usex doc true false)
+ -Ddebug-refcounting=$(usex debug true false)
+ -Dbuild-examples=false
+ )
+ meson_src_configure
+}
+
+multilib_src_compile() {
+ meson_src_compile
+}
+
+multilib_src_test() {
+ meson_src_test
+}
+
+multilib_src_install() {
+ meson_src_install
+}