dev-games/KXL: add 1.1.7_p17 (switch to Debian patches)

Indeed, most of our patches game from Debian (albeit without references ;))
so this is far simpler.

Dates back a long time!
```
+*KXL-1.1.7-r1 (13 May 2007)
+
+  13 May 2007; Tupone Alfredo <tupone@gentoo.org>
+  +files/KXL-1.1.7-amd64.patch, +KXL-1.1.7-r1.ebuild:
+  Fixing bug #148332 by Pacho Ramos
+  Patch are from debian. It regards 64bit, sound and autorepeat
```

Bug: https://bugs.gentoo.org/148332
Closes: https://bugs.gentoo.org/870415
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-games/KXL/KXL-1.1.7_p17.ebuild b/dev-games/KXL/KXL-1.1.7_p17.ebuild
new file mode 100644
index 000000000000..33e072b293c6
--- /dev/null
+++ b/dev-games/KXL/KXL-1.1.7_p17.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_PV=$(ver_cut 1-3)
+DESCRIPTION="Development Library for making games for X"
+HOMEPAGE="http://kxl.orz.hm/"
+# http://kxl.hn.org/download/${P}.tar.gz
+SRC_URI="mirror://debian/pool/main/k/kxl/kxl_${MY_PV}.orig.tar.gz -> ${PN}-${MY_PV}.tar.gz"
+SRC_URI+=" mirror://debian/pool/main/k/kxl/kxl_${MY_PV}-$(ver_cut 5).debian.tar.xz"
+S="${WORKDIR}"/${PN}-${MY_PV}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="x11-libs/libX11"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-${MY_PV}-as-needed.patch
+	"${FILESDIR}"/${PN}-${MY_PV}-ldflags.patch
+	"${FILESDIR}"/${PN}-${MY_PV}-implicit-function-declarations.patch
+)
+
+src_prepare() {
+	drop_debian_patch() {
+		rm "${WORKDIR}"/debian/patches/$1 || die
+		sed -i -e "/^${1}/d" "${WORKDIR}"/debian/patches/series || die
+	}
+
+	drop_debian_patch 000_soname_xlibs.diff
+
+	eapply $(awk '{print $1}' "${WORKDIR}"/debian/patches/series | sed -e "s:^:${WORKDIR}/debian/patches/:")
+
+	default
+
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}