dev-lang/nasm: bump up to 2.14, bug #670884

Reported-by: Arfrever Frehtes Taifersar Arahesis
Bug: https://bugs.gentoo.org/670884
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-lang/nasm/nasm-2.14.ebuild b/dev-lang/nasm/nasm-2.14.ebuild
new file mode 100644
index 000000000000..46c8d440a406
--- /dev/null
+++ b/dev-lang/nasm/nasm-2.14.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+DESCRIPTION="groovy little assembler"
+HOMEPAGE="https://www.nasm.us/"
+SRC_URI="https://www.nasm.us/pub/nasm/releasebuilds/${PV/_}/${P/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~x86 ~x64-cygwin ~amd64-fbsd ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND=""
+DEPEND=""
+# [fonts note] doc/psfonts.ph defines ordered list of font preference.
+# Currently 'media-fonts/source-pro' is most preferred and is able to
+# satisfy all 6 font flavours: tilt, chapter, head, etc.
+BDEPEND="
+	dev-lang/perl
+	doc? (
+		app-text/ghostscript-gpl
+		dev-perl/Font-TTF
+		dev-perl/Sort-Versions
+		media-fonts/source-pro
+		virtual/perl-File-Spec
+	)
+"
+
+S=${WORKDIR}/${P/_}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.13.03-bsd-cp-doc.patch
+)
+
+src_configure() {
+	strip-flags
+	default
+}
+
+src_compile() {
+	default
+	use doc && emake doc
+}
+
+src_install() {
+	default
+	emake DESTDIR="${D}" install_rdf $(usex doc install_doc '')
+}