summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2018-12-19 00:37:36 +0000
committerSergei Trofimovich <slyfox@gentoo.org>2018-12-19 07:22:04 +0000
commite477d6aca1b5848044ed2f72fe6d78e7f5b966cd (patch)
tree2fda8479de185839b588998f2958adcacc956450 /dev-libs/capstone/capstone-4.0.ebuild
parentdev-ada/gps-bin: Maintainer ada@gentoo.org (diff)
downloadgentoo-e477d6aca1b5848044ed2f72fe6d78e7f5b966cd.tar.gz
gentoo-e477d6aca1b5848044ed2f72fe6d78e7f5b966cd.tar.bz2
gentoo-e477d6aca1b5848044ed2f72fe6d78e7f5b966cd.zip
dev-libs/capstone: bump up to 4.0
Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Diffstat (limited to 'dev-libs/capstone/capstone-4.0.ebuild')
-rw-r--r--dev-libs/capstone/capstone-4.0.ebuild85
1 files changed, 85 insertions, 0 deletions
diff --git a/dev-libs/capstone/capstone-4.0.ebuild b/dev-libs/capstone/capstone-4.0.ebuild
new file mode 100644
index 00000000000..78213838489
--- /dev/null
+++ b/dev-libs/capstone/capstone-4.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="disassembly/disassembler framework + bindings"
+HOMEPAGE="http://www.capstone-engine.org/"
+SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4" # libcapstone.so.4
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="python"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+ python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-FLAGS.patch
+ "${FILESDIR}"/${P}-no-fuzz-tests.patch
+ "${FILESDIR}"/${P}-double-DESTDIR.patch
+)
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+wrap_python() {
+ if use python; then
+ pushd bindings/python >/dev/null || die
+ distutils-r1_${1} "$@"
+ popd >/dev/null
+ fi
+}
+
+src_prepare() {
+ default
+
+ wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+ {
+ cat <<-EOF
+ # Gentoo overrides:
+ # verbose build
+ V = 1
+ # toolchain
+ AR = $(tc-getAR)
+ CC = $(tc-getCC)
+ RANLIB = $(tc-getRANLIB)
+ # toolchain flags
+ CFLAGS = ${CFLAGS}
+ LDFLAGS = ${LDFLAGS}
+ # libs
+ LIBDIRARCH = $(get_libdir)
+ EOF
+ } >> config.mk || die
+
+ wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+ default
+
+ wrap_python ${FUNCNAME}
+}
+
+src_test() {
+ default
+
+ wrap_python ${FUNCNAME}
+}
+
+src_install() {
+ default
+
+ wrap_python ${FUNCNAME}
+}