summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLuke Dashjr <luke-jr+git@utopios.org>2020-09-29 14:16:17 +0000
committerJoonas Niilola <juippis@gentoo.org>2020-10-05 08:46:48 +0300
commit3d002a389dc3e77943ce1d689e85aa3548793dc6 (patch)
tree312513f871058f823d9111d5219be449c328d67c /dev-libs/libbase58
parentnet-analyzer/sslscan: add 2.0.2 (diff)
downloadgentoo-3d002a389dc3e77943ce1d689e85aa3548793dc6.tar.gz
gentoo-3d002a389dc3e77943ce1d689e85aa3548793dc6.tar.bz2
gentoo-3d002a389dc3e77943ce1d689e85aa3548793dc6.zip
dev-libs/libbase58: Add multilib support to 0.1.4
Also adds a missing dependency on libgcrypt for test & USE=tools Signed-off-by: Luke Dashjr <luke-jr+git@utopios.org> Signed-off-by: Joonas Niilola <juippis@gentoo.org>
Diffstat (limited to 'dev-libs/libbase58')
-rw-r--r--dev-libs/libbase58/libbase58-0.1.4-r1.ebuild48
1 files changed, 48 insertions, 0 deletions
diff --git a/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild b/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild
new file mode 100644
index 00000000000..6d58a9ccec7
--- /dev/null
+++ b/dev-libs/libbase58/libbase58-0.1.4-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="C implementation of Bitcoin's base58 encoding"
+HOMEPAGE="https://github.com/luke-jr/libbase58"
+LICENSE="MIT"
+
+SRC_URI="https://github.com/luke-jr/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="test tools"
+RESTRICT="!test? ( test )"
+
+# NOTE: If not testing, we don't need non-native libgcrypt
+RDEPEND="tools? ( dev-libs/libgcrypt )"
+DEPEND="${RDEPEND}
+ test? ( dev-libs/libgcrypt[${MULTILIB_USEDEP}] )
+"
+
+src_prepare() {
+ eapply_user
+ eautoreconf
+
+ # NOTE: Needed because test suite uses srcdir instead of builddir to set PATH
+ multilib_copy_sources
+}
+
+multilib_src_configure() {
+ local myeconf=(
+ --disable-static
+ LIBGCRYPT_CONFIG="${EPREFIX}/usr/bin/${CHOST}-libgcrypt-config"
+ )
+ if multilib_is_native_abi && use tools; then
+ myeconf+=( --enable-tool )
+ elif use test; then
+ myeconf+=( --enable-tool --bindir='/TRASH' )
+ else
+ myeconf+=( --disable-tool )
+ fi
+ econf "${myeconf[@]}"
+}
+
+multilib_src_install_all() {
+ rm -rf "${ED}/TRASH" || die
+}