summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJeroen Roovers <jer@gentoo.org>2020-07-29 11:44:12 +0200
committerJeroen Roovers <jer@gentoo.org>2020-07-29 11:45:00 +0200
commit1b3196dc85f070f271e4bc9c26daa42ae328ffce (patch)
treeea7b992096e9dcf10a6de7e352b1ec48aa19bdfe /dev-libs/liblinear/liblinear-241.ebuild
parentnet-analyzer/hydra: Old (diff)
downloadgentoo-1b3196dc85f070f271e4bc9c26daa42ae328ffce.tar.gz
gentoo-1b3196dc85f070f271e4bc9c26daa42ae328ffce.tar.bz2
gentoo-1b3196dc85f070f271e4bc9c26daa42ae328ffce.zip
dev-libs/liblinear: Version 241
Package-Manager: Portage-3.0.1, Repoman-2.3.23 Signed-off-by: Jeroen Roovers <jer@gentoo.org>
Diffstat (limited to 'dev-libs/liblinear/liblinear-241.ebuild')
-rw-r--r--dev-libs/liblinear/liblinear-241.ebuild52
1 files changed, 52 insertions, 0 deletions
diff --git a/dev-libs/liblinear/liblinear-241.ebuild b/dev-libs/liblinear/liblinear-241.ebuild
new file mode 100644
index 00000000000..ede9a159d95
--- /dev/null
+++ b/dev-libs/liblinear/liblinear-241.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+inherit multilib toolchain-funcs
+
+DESCRIPTION="A Library for Large Linear Classification"
+HOMEPAGE="https://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
+SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e '/^AR/s|=|?=|g' \
+ -e '/^RANLIB/s|=|?=|g' \
+ -e '/^CFLAGS/d;/^CXXFLAGS/d' \
+ blas/Makefile || die
+ sed -i \
+ -e 's|make|$(MAKE)|g' \
+ -e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
+ -e '/^CFLAGS/d;/^CXXFLAGS/d' \
+ -e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
+ Makefile || die
+}
+
+src_compile() {
+ emake \
+ CC="$(tc-getCC)" \
+ CXX="$(tc-getCXX)" \
+ CFLAGS="${CFLAGS} -fPIC" \
+ CXXFLAGS="${CXXFLAGS} -fPIC" \
+ AR="$(tc-getAR) rcv" \
+ RANLIB="$(tc-getRANLIB)" \
+ lib all
+}
+
+src_install() {
+ dolib.so ${PN}.so.4
+ dosym ${PN}.so.4 /usr/$(get_libdir)/${PN}.so
+
+ newbin predict ${PN}-predict
+ newbin train ${PN}-train
+
+ doheader linear.h
+
+ dodoc README
+}