dev-libs/libthreadar: stop building examples

There are example binaries that do not get installed.  One links
statically, one cannot be built with slibtool.  Skip building them
altogether.
Disable building the docs, fix automagic dependency on doxygen.

Closes: https://bugs.gentoo.org/934522
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

1 files changed, 35 insertions, 0 deletions

diff --git a/dev-libs/libthreadar/libthreadar-1.4.0-r1.ebuild b/dev-libs/libthreadar/libthreadar-1.4.0-r1.ebuild
new file mode 100644
index 000000000000..8f5114cc1805
--- /dev/null
+++ b/dev-libs/libthreadar/libthreadar-1.4.0-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Threading library used by dar archiver"
+HOMEPAGE="https://sourceforge.net/projects/libthreadar/"
+SRC_URI="https://downloads.sourceforge.net/libthreadar/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+src_prepare() {
+	default
+
+	# don't build examples, they are not installed
+	sed -i -e '/^SUBDIRS =/d' doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-build-html
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+	rm -r "${ED}"/usr/share/doc/${PF}/html || die
+
+	find "${ED}" -name '*.la' -delete || die
+}