dev-libs/mongo-c-driver: bump to v1.18.0

Package-Manager: Portage-3.0.21, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/dev-libs/mongo-c-driver/Manifest b/dev-libs/mongo-c-driver/Manifest
index 4a1d6bdc1f01..51ab9f632e96 100644
--- a/dev-libs/mongo-c-driver/Manifest
+++ b/dev-libs/mongo-c-driver/Manifest
@@ -1,2 +1,3 @@
 DIST mongo-c-driver-1.16.2.tar.gz 6888287 BLAKE2B 40d2b73f495a8c71ca8b3c39c1b3c85b4a01ea088428967ed49f4758ef749e3288b046bde767a83aad022933f30f7307a4be65141f477bb1dcf912b4099129d6 SHA512 0930a80692f08329cad558644c25c46da64a0c8b6a9fc7412db0f547dae63bf59e9d29ee774d329c63af186eea751670bf21ccee8cf255f8bc8d5bd78c0e736a
 DIST mongo-c-driver-1.17.0.tar.gz 7092911 BLAKE2B f93de6f3ded0f22ff8af65113ed207ca6dcc8ecbaedb24b33ddf7ada93b913eae33a802245f386d75fef01bf53c2d9630e68138a5715de001b7acea7dbde05f1 SHA512 49889b9d777dc3cb151b9cbef7bc2dd1785e327ae641569281efcc040d208cb034da3a74ae1115a033cc86e5b70079dab76c3478df8f171cc083d686f7568858
+DIST mongo-c-driver-1.18.0.tar.gz 7246954 BLAKE2B 9418ab2e132f8a8c582bcbea8c7b090e9e45e34219845d8f6b7a99d4ebfb17ef2eec2223504e9a4ab7f51ca01e904a7f3bb04bf9f8bf20c010ab9f82894a728e SHA512 c970f347689916172a957fc431b307bab3cb63367d4b39c49745c75b9fa84f0035db934c551570a4141733fc1bc6b33b118911c3b69ecdea797f19312b213606
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-1.18.0.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-1.18.0.ebuild
new file mode 100644
index 000000000000..706008e92748
--- /dev/null
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-1.18.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Client library written in C for MongoDB"
+HOMEPAGE="https://github.com/mongodb/mongo-c-driver"
+SRC_URI="https://github.com/mongodb/mongo-c-driver/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~s390 ~x86"
+IUSE="debug examples icu sasl ssl static-libs test"
+REQUIRED_USE="test? ( static-libs )"
+
+# No tests on x86 because tests require dev-db/mongodb which don't support
+# x86 anymore (bug #645994)
+RESTRICT="x86? ( test )
+	!test? ( test )"
+
+RDEPEND="app-arch/snappy:=
+	app-arch/zstd:=
+	>=dev-libs/libbson-${PV}[static-libs?]
+	dev-python/sphinx
+	sys-libs/zlib:=
+	icu? ( dev-libs/icu:= )
+	sasl? ( dev-libs/cyrus-sasl:= )
+	ssl? (
+		dev-libs/openssl:0=
+	)"
+DEPEND="${RDEPEND}
+	test? (
+		dev-db/mongodb
+		dev-libs/libbson[static-libs]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.14.0-no-docs.patch"
+	"${FILESDIR}/${PN}-1.16.2-enable-tests.patch" # enable tests with system libbson
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# copy private headers for tests since we don't build libbson
+	if use test; then
+		mkdir -p src/libbson/tests/bson || die
+		cp src/libbson/src/bson/bson-*.h src/libbson/tests/bson/ || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON # mongoc-stat insecure runpath
+		-DENABLE_BSON=SYSTEM
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_ICU="$(usex icu ON OFF)"
+		-DENABLE_MAN_PAGES=ON
+		-DENABLE_MONGOC=ON
+		-DENABLE_SNAPPY=SYSTEM
+		-DENABLE_ZLIB=SYSTEM
+		-DENABLE_SASL="$(usex sasl CYRUS OFF)"
+		-DENABLE_SSL="$(usex ssl OPENSSL OFF )"
+		-DENABLE_STATIC="$(usex static-libs ON OFF)"
+		-DENABLE_TESTS="$(usex test ON OFF)"
+		-DENABLE_TRACING="$(usex debug ON OFF)"
+		-DENABLE_UNINSTALL=OFF
+		-DENABLE_ZSTD=ON
+	)
+
+	cmake_src_configure
+}
+
+# FEATURES="test -network-sandbox" USE="static-libs" emerge dev-libs/mongo-c-driver
+src_test() {
+	local PORT=27099
+	mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
+		--dbpath="${T}" --logpath="${T}/mongod.log" || die
+	MONGOC_TEST_URI="mongodb://[127.0.0.1]:${PORT}" ../mongo-c-driver-${PV}_build/src/libmongoc/test-libmongoc || die
+	kill $(<"${T}/mongod.lock")
+}
+
+src_install() {
+	if use examples; then
+		docinto examples
+		dodoc src/libmongoc/examples/*.c
+	fi
+
+	cmake_src_install
+}