summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2021-03-04 04:55:28 +0000
committerSam James <sam@gentoo.org>2021-03-04 04:55:28 +0000
commitfd4009b59a9082b52b8dbef42d5cfa737f4ade2b (patch)
tree0eac65c11b4b20874d1b5a61bfde44e1fb9f07de /dev-libs/tomsfastmath
parentnet-analyzer/nmap: remove old (diff)
downloadgentoo-fd4009b59a9082b52b8dbef42d5cfa737f4ade2b.tar.gz
gentoo-fd4009b59a9082b52b8dbef42d5cfa737f4ade2b.tar.bz2
gentoo-fd4009b59a9082b52b8dbef42d5cfa737f4ade2b.zip
dev-libs/tomsfastmath: remove 0.13.1
Signed-off-by: Sam James <sam@gentoo.org>
Diffstat (limited to 'dev-libs/tomsfastmath')
-rw-r--r--dev-libs/tomsfastmath/tomsfastmath-0.13.1.ebuild69
1 files changed, 0 insertions, 69 deletions
diff --git a/dev-libs/tomsfastmath/tomsfastmath-0.13.1.ebuild b/dev-libs/tomsfastmath/tomsfastmath-0.13.1.ebuild
deleted file mode 100644
index 708ecd1d02a..00000000000
--- a/dev-libs/tomsfastmath/tomsfastmath-0.13.1.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit toolchain-funcs
-
-DESCRIPTION="Fast public domain large integer arithmetic library"
-HOMEPAGE="https://www.libtom.net/TomsFastMath/
- https://github.com/libtom/tomsfastmath"
-SRC_URI="https://github.com/libtom/tomsfastmath/releases/download/v${PV}/tfm-${PV}.tar.xz"
-
-LICENSE="Unlicense"
-# Current SONAME is 1
-# Please bump when the ABI changes upstream
-# Helpful site:
-# https://abi-laboratory.pro/index.php?view=timeline&l=tomsfastmath
-SLOT="0/1"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~sparc x86"
-
-BDEPEND="sys-devel/libtool"
-
-PATCHES=(
- "${FILESDIR}/${P}-makefile-fix.patch"
-)
-
-_emake() {
- # Standard boilerplate
- # Upstream use homebrewed makefiles
- # Best to use same args for all, for consistency,
- # in case behaviour changes (v possible).
- emake \
- CC="$(tc-getCC)" \
- AR="$(tc-getAR)" \
- RANLIB="$(tc-getRANLIB)" \
- DESTDIR="${ED}" \
- LIBPATH="/usr/$(get_libdir)" \
- IGNORE_SPEED=1 \
- "$@"
-}
-
-src_compile() {
- _emake -f makefile.shared
-}
-
-src_test() {
- _emake test_standalone stest rsatest
-
- # We choose to be verbose during the test process
- # because the output is quite repetitive with no
- # clear demarcation b/t tests
- local tests=( "test" "stest" "rsatest" )
-
- local test
- for test in "${tests[@]}"; do
- einfo "Running test (${test})"
- ./${test} || die "Test (${test}) failed"
- einfo "Completed test (${test})"
- done
-}
-
-src_install() {
- _emake -f makefile.shared install
-
- # Remove unnecessary .la files
- find "${ED}" -name '*.la' -delete || die
- # Same for static libs
- find "${ED}" -name "*.a" -delete || die
-}