summaryrefslogtreecommitdiff
path: root/dev-ml
diff options
context:
space:
mode:
authorAlexis Ballier <aballier@gentoo.org>2016-09-06 16:13:21 +0200
committerAlexis Ballier <aballier@gentoo.org>2016-09-06 16:17:21 +0200
commit58fd5dcd4938a9f962654880520b9e57322080a3 (patch)
tree266966f4d561de2cab7a6dca2c52158bbb79f1d6 /dev-ml
parentwww-servers/ocsigenserver: remove keywords from live ebuild (diff)
downloadgentoo-58fd5dcd4938a9f962654880520b9e57322080a3.tar.gz
gentoo-58fd5dcd4938a9f962654880520b9e57322080a3.tar.bz2
gentoo-58fd5dcd4938a9f962654880520b9e57322080a3.zip
dev-ml/eliom: add live ebuild
Package-Manager: portage-2.3.0
Diffstat (limited to 'dev-ml')
-rw-r--r--dev-ml/eliom/eliom-9999.ebuild67
1 files changed, 67 insertions, 0 deletions
diff --git a/dev-ml/eliom/eliom-9999.ebuild b/dev-ml/eliom/eliom-9999.ebuild
new file mode 100644
index 00000000000..f4089655228
--- /dev/null
+++ b/dev-ml/eliom/eliom-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils multilib findlib
+
+DESCRIPTION="A web framework to program client/server applications"
+HOMEPAGE="http://ocsigen.org/eliom/"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+ inherit git-r3
+ SRC_URI=""
+ EGIT_REPO_URI="https://github.com/ocsigen/eliom"
+ KEYWORDS=""
+else
+ SRC_URI="https://github.com/ocsigen/eliom/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+IUSE="doc +ocamlopt +ppx"
+
+RDEPEND=">=dev-lang/ocaml-4.03:=[ocamlopt?]
+ >=dev-ml/js_of_ocaml-2.5-r1:=
+ >=www-servers/ocsigenserver-2.5:=
+ >=dev-ml/tyxml-4:=
+ >=dev-ml/deriving-0.6:=
+ >=dev-ml/reactiveData-0.2:=
+ dev-ml/ocaml-ipaddr:=
+ dev-ml/react:=
+ dev-ml/ocaml-ssl:=
+ >=dev-ml/lwt-2.5.0:=
+ dev-ml/calendar:=
+ dev-ml/camlp4:=
+ ppx? ( >=dev-ml/ppx_tools-0.99.3:= )"
+DEPEND="${RDEPEND}
+ dev-ml/ocamlbuild
+ dev-ml/opam"
+
+src_compile() {
+ if use ocamlopt ; then
+ emake PPX=$(usex ppx true false) all
+ else
+ emake PPX=$(usex ppx true false) byte
+ fi
+ use doc && emake doc
+ emake man
+}
+
+src_install() {
+ opam-installer \
+ --prefix="${ED}/usr" \
+ --libdir="${D}/$(ocamlc -where)" \
+ --docdir="${ED}/usr/share/doc/${PF}" \
+ --mandir="${ED}/usr/share/man" \
+ || die
+ dodoc CHANGES README.md
+ if use doc ; then
+ docinto client/html
+ dodoc -r _build/src/lib/client/api.docdir/*
+ docinto server/html
+ dodoc -r _build/src/lib/server/api.docdir/*
+ fi
+}