summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorThomas Deutschmann <whissi@gentoo.org>2021-02-09 18:56:15 +0100
committerThomas Deutschmann <whissi@gentoo.org>2021-02-09 19:43:50 +0100
commitb49acf108677620e61279a8abffe382b30b2e605 (patch)
tree8b3111bf98413be274f8ea5d6932ce817c2bac89 /dev-php/phing/phing-2.16.4.ebuild
parentnet-dns/dnsviz: bump to v0.9.2 (diff)
downloadgentoo-b49acf108677620e61279a8abffe382b30b2e605.tar.gz
gentoo-b49acf108677620e61279a8abffe382b30b2e605.tar.bz2
gentoo-b49acf108677620e61279a8abffe382b30b2e605.zip
dev-php/phing: bump to v2.16.4
Package-Manager: Portage-3.0.14, Repoman-3.0.2 Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
Diffstat (limited to 'dev-php/phing/phing-2.16.4.ebuild')
-rw-r--r--dev-php/phing/phing-2.16.4.ebuild57
1 files changed, 57 insertions, 0 deletions
diff --git a/dev-php/phing/phing-2.16.4.ebuild b/dev-php/phing/phing-2.16.4.ebuild
new file mode 100644
index 00000000000..7d5bc50b8c7
--- /dev/null
+++ b/dev-php/phing/phing-2.16.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="PHP project build system based on Apache Ant"
+HOMEPAGE="https://www.phing.info/"
+SRC_URI="https://www.phing.info/get/${P}.tgz"
+
+LICENSE="FDL-1.3 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples minimal zip"
+
+RDEPEND="dev-lang/php:*[cli,xml,xslt,zip?]
+ dev-php/symfony-yaml
+ !minimal? (
+ dev-php/PEAR-HTTP_Request2
+ dev-php/PEAR-PEAR_PackageFileManager
+ dev-php/PEAR-VersionControl_SVN
+ dev-php/PHP_CodeCoverage
+ dev-php/phpDocumentor
+ dev-php/phpmd
+ dev-php/phpunit
+ dev-php/simpletest
+ dev-php/xdebug
+ )"
+
+S="${WORKDIR}"
+
+src_install() {
+ dodoc CHANGELOG.md CREDITS.md README.md
+ dodoc -r docs/docbook5/en/output/hlhtml
+ use doc && dodoc -r docs/api
+ use examples && dodoc -r docs/example
+
+ # Install the executable (and the PHP file it wraps) outside of the
+ # PHP include directory, since nobody should be including it.
+ exeinto "/usr/share/${PN}/bin"
+ doexe "bin/${PN}"
+ insinto "/usr/share/${PN}/bin"
+ doins "bin/${PN}.php"
+ dosym "../share/${PN}/bin/${PN}" "/usr/bin/${PN}"
+
+ # Phing tries to get the version number from this file.
+ insinto "/usr/share/${PN}/etc"
+ doins etc/VERSION.TXT
+
+ # The executable will only look for autoload.php in one place, so we
+ # create an (otherwise pointless) vendor directory to house it.
+ insinto "/usr/share/${PN}/vendor"
+ doins "${FILESDIR}/autoload.php"
+
+ # But install the library under /usr/share/php.
+ insinto "/usr/share/php"
+ doins -r "classes/${PN}"
+}