summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2020-07-30 07:34:40 +0200
committerMichał Górny <mgorny@gentoo.org>2020-07-30 08:02:50 +0200
commit93a8328a0094340823767ef5a0a4e8047c14ef9a (patch)
treec13fd22267a0a0c10ee4493d0923dc6769b92949 /dev-python/boto3/boto3-1.14.31.ebuild
parentdev-python/botocore: Bump to 1.17.31 (diff)
downloadgentoo-93a8328a0094340823767ef5a0a4e8047c14ef9a.tar.gz
gentoo-93a8328a0094340823767ef5a0a4e8047c14ef9a.tar.bz2
gentoo-93a8328a0094340823767ef5a0a4e8047c14ef9a.zip
dev-python/boto3: Bump to 1.14.31
Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'dev-python/boto3/boto3-1.14.31.ebuild')
-rw-r--r--dev-python/boto3/boto3-1.14.31.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/boto3/boto3-1.14.31.ebuild b/dev-python/boto3/boto3-1.14.31.ebuild
new file mode 100644
index 00000000000..74bb826bd08
--- /dev/null
+++ b/dev-python/boto3/boto3-1.14.31.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/boto/boto3"
+ inherit git-r3
+ BOTOCORE_PV=${PV}
+else
+ SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+ # botocore is x.(y+3).z
+ BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+ >=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+ >=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+ >=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/mock[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs/source \
+ 'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+ # don't lock versions to narrow ranges
+ sed -e '/botocore/ d' \
+ -e '/jmespath/ d' \
+ -e '/s3transfer/ d' \
+ -i setup.py || die
+
+ # prevent an infinite loop
+ rm tests/functional/docs/test_smoke.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}