dev-python/cssutils: enable support for Python 3.5

- revbump for 0.9.10
- silent add for 1.0 and 1.0.1

Package-Manager: portage-2.2.26
RepoMan-Options: --ignore-arches

3 files changed, 50 insertions, 4 deletions

diff --git a/dev-python/cssutils/cssutils-0.9.10-r2.ebuild b/dev-python/cssutils/cssutils-0.9.10-r2.ebuild
new file mode 100644
index 000000000000..1c74279ae29f
--- /dev/null
+++ b/dev-python/cssutils/cssutils-0.9.10-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} pypy )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="A CSS Cascading Style Sheets library"
+HOMEPAGE="https://pypi.python.org/pypi/cssutils/ https://bitbucket.org/cthedot/cssutils"
+# Missing test data
+# https://bitbucket.org/cthedot/cssutils/pull-request/11
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+HG_COMMIT="6fbc1877f6089610b733a92d21c2bbf25dc1ca28"
+SRC_URI="https://bitbucket.org/cthedot/cssutils/get/${HG_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="examples test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Disable test failing with dev-python/pyxml installed.
+	if has_version dev-python/pyxml; then
+		sed -e "s/test_linecol/_&/" -i src/tests/test_errorhandler.py
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	ln -s "${S}/sheets" "${BUILD_DIR}/sheets" || die
+	set --  nosetests -P "${BUILD_DIR}/lib/cssutils/tests"
+	echo "$@"
+	"$@" || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/cssutils/cssutils-1.0.1.ebuild b/dev-python/cssutils/cssutils-1.0.1.ebuild
index d585a639942d..3553d268297c 100644
--- a/dev-python/cssutils/cssutils-1.0.1.ebuild
+++ b/dev-python/cssutils/cssutils-1.0.1.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
 EAPI=5
-PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} pypy )
 
 inherit distutils-r1
 
diff --git a/dev-python/cssutils/cssutils-1.0.ebuild b/dev-python/cssutils/cssutils-1.0.ebuild
index 1e5aa368739b..1a0487d349ee 100644
--- a/dev-python/cssutils/cssutils-1.0.ebuild
+++ b/dev-python/cssutils/cssutils-1.0.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
 EAPI=5
-PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} pypy )
 
 inherit distutils-r1 vcs-snapshot