summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2020-02-26 13:49:05 +0100
committerLars Wendler <polynomial-c@gentoo.org>2020-02-26 13:56:41 +0100
commitc6903891b7b66545185f02ca35db56ff50e98fa9 (patch)
tree5c5e0c5c9ed28fee865439431077dd1d2439db19 /dev-python/dbus-python/dbus-python-1.2.16.ebuild
parentdev-lang/erlang: bump up to 22.2.7 (diff)
downloadgentoo-c6903891b7b66545185f02ca35db56ff50e98fa9.tar.gz
gentoo-c6903891b7b66545185f02ca35db56ff50e98fa9.tar.bz2
gentoo-c6903891b7b66545185f02ca35db56ff50e98fa9.zip
dev-python/dbus-python: Bump to version 1.2.16
Package-Manager: Portage-2.3.89, Repoman-2.3.20 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'dev-python/dbus-python/dbus-python-1.2.16.ebuild')
-rw-r--r--dev-python/dbus-python/dbus-python-1.2.16.ebuild77
1 files changed, 77 insertions, 0 deletions
diff --git a/dev-python/dbus-python/dbus-python-1.2.16.ebuild b/dev-python/dbus-python/dbus-python-1.2.16.ebuild
new file mode 100644
index 00000000000..7c3a124a8e9
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.16.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+ >=sys-apps/dbus-1.8:=
+ >=dev-libs/glib-2.40
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+ doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+ test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/tappy[${PYTHON_USEDEP}] )
+"
+
+python_check_deps() {
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+ default
+ # Update py-compile, bug 529502.
+ eautoreconf
+ python_copy_sources
+}
+
+src_configure() {
+ use doc && python_setup
+ local SPHINX_IMPL=${EPYTHON}
+
+ configuring() {
+ local myconf=(
+ --disable-documentation
+ )
+ [[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+ myconf+=( --enable-documentation )
+
+ econf "${myconf[@]}"
+ }
+ python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+ python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+ unset DBUS_SESSION_BUS_ADDRESS
+ python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+ python_foreach_impl run_in_build_dir default
+ find "${D}" -name '*.la' -type f -delete || die
+
+ use examples && dodoc -r examples
+}