summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2019-12-02 13:55:11 +0100
committerLars Wendler <polynomial-c@gentoo.org>2019-12-02 13:56:57 +0100
commitc9c91b9663e8dcb2d8dacf92761e8aa7fc231e2b (patch)
tree3545a1624695e8b1ccd3994bae7dbe39da1e8377 /dev-python/dbus-python
parentdev-python/jaraco-text: remove old (diff)
downloadgentoo-c9c91b9663e8dcb2d8dacf92761e8aa7fc231e2b.tar.gz
gentoo-c9c91b9663e8dcb2d8dacf92761e8aa7fc231e2b.tar.bz2
gentoo-c9c91b9663e8dcb2d8dacf92761e8aa7fc231e2b.zip
dev-python/dbus-python: Bump to version 1.2.14
which fixes python-3.8 issues Package-Manager: Portage-2.3.80, Repoman-2.3.19 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Diffstat (limited to 'dev-python/dbus-python')
-rw-r--r--dev-python/dbus-python/Manifest1
-rw-r--r--dev-python/dbus-python/dbus-python-1.2.14.ebuild78
2 files changed, 79 insertions, 0 deletions
diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
index 0e3f445385a..ab0fb118655 100644
--- a/dev-python/dbus-python/Manifest
+++ b/dev-python/dbus-python/Manifest
@@ -1,2 +1,3 @@
DIST dbus-python-1.2.12.tar.gz 574727 BLAKE2B e5516e7109fad089af51d3e5db3921d056f327c27f9b74a870b1b31b04ba952ad3c9ba5916a18d674ab1179b94cf516b24e046feded8f2e542b196d162038944 SHA512 6f90eaeeb74ea71a026a331d4c611911eda6dfb6c9086a0a80352f9963a9ae126db6f3e32d183916b8517f177fc947f1ddb15df83ff0b5c886532116868383b4
+DIST dbus-python-1.2.14.tar.gz 576181 BLAKE2B 4e36c3d0ed07ce6c7514e2699b6cf5d0a75332c8dab3ca90e2d451d6649c26f61b2173b4b7f230c54df2b9f4214d0f3c54a45c233d6e8fd38bf39a6312f480fc SHA512 773d66e40ab514639f1c5c619362659f290ddd5ae944eb8e09b5752624f3c86305b6c1d5562e290b36f1e6cf43f6d39cd4a227e18ff41499877546982ceebb51
DIST dbus-python-1.2.4.tar.gz 612112 BLAKE2B cccd3e2f5d700c0d228e7d21fd85e2307357778371742a7fe26a0e419af41886efebb27a73f642d2ecd4603c79f4afe6e7002af95c831180e0e7844c079b2c8c SHA512 efdd9d96a8b56e813c93208d34777f1ca2db96c076d31f13afbcaec3c7770a16a623d5531fe23443130c555240949802503f171f2064d45eee97546d6251304b
diff --git a/dev-python/dbus-python/dbus-python-1.2.14.ebuild b/dev-python/dbus-python/dbus-python-1.2.14.ebuild
new file mode 100644
index 00000000000..5526593b6e8
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.14.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+ >=sys-apps/dbus-1.8:=
+ >=dev-libs/glib-2.40
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+ test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/tappy[${PYTHON_USEDEP}] )
+"
+
+python_check_deps() {
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+ default
+ # Update py-compile, bug 529502.
+ eautoreconf
+ python_copy_sources
+}
+
+src_configure() {
+ use doc && python_setup
+ local SPHINX_IMPL=${EPYTHON}
+
+ configuring() {
+ local myconf=(
+ --disable-documentation
+ )
+ [[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+ myconf+=( --enable-documentation )
+
+ econf "${myconf[@]}"
+ }
+ python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+ python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+ unset DBUS_SESSION_BUS_ADDRESS
+ python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+ python_foreach_impl run_in_build_dir default
+ find "${D}" -name '*.la' -type f -delete || die
+
+ use examples && dodoc -r examples
+}