proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-python/enable/enable-4.4.1.ebuild b/dev-python/enable/enable-4.4.1.ebuild
new file mode 100644
index 000000000000..7987e1a87db2
--- /dev/null
+++ b/dev-python/enable/enable-4.4.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx flag-o-matic
+
+DESCRIPTION="Enthought Tool Suite: Drawing and interaction packages"
+HOMEPAGE="http://code.enthought.com/projects/enable/ http://pypi.python.org/pypi/enable"
+SRC_URI="https://github.com/enthought/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/reportlab[${PYTHON_USEDEP}]
+	>=dev-python/traitsui-4[${PYTHON_USEDEP}]
+	>=media-libs/freetype-2
+	virtual/opengl
+	virtual/glu
+	x11-libs/libX11"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-lang/swig:0
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)"
+
+python_prepare_all() {
+	append-cflags -fno-strict-aliasing
+
+	sed -e 's:html_favicon = "et.ico":html_favicon = "_static/et.ico":' \
+		-i docs/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	pushd "${BUILD_DIR}"/lib > /dev/null
+	# https://github.com/enthought/enable/issues/158
+	PYTHONPATH=.:kiva \
+		VIRTUALX_COMMAND="nosetests" virtualmake
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}