summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2024-04-11 06:02:53 +0200
committerMichał Górny <mgorny@gentoo.org>2024-04-11 06:20:06 +0200
commita7c6dd17baa88631b2a2f9d59132b5c519258d6a (patch)
tree511b7fe54f27de9606b193ee9f7db6b82e558a26 /dev-python/mako/mako-1.3.3.ebuild
parentdev-python/openapi-core: Bump to 0.19.1 (diff)
downloadgentoo-a7c6dd17baa88631b2a2f9d59132b5c519258d6a.tar.gz
gentoo-a7c6dd17baa88631b2a2f9d59132b5c519258d6a.tar.bz2
gentoo-a7c6dd17baa88631b2a2f9d59132b5c519258d6a.zip
dev-python/mako: Bump to 1.3.3
Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'dev-python/mako/mako-1.3.3.ebuild')
-rw-r--r--dev-python/mako/mako-1.3.3.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/mako/mako-1.3.3.ebuild b/dev-python/mako/mako-1.3.3.ebuild
new file mode 100644
index 000000000000..2069ece40b7a
--- /dev/null
+++ b/dev-python/mako/mako-1.3.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="
+ https://www.makotemplates.org/
+ https://github.com/sqlalchemy/mako/
+ https://pypi.org/project/Mako/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND="
+ >=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/Babel[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=()
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ test/test_exceptions.py::ExceptionsTest::test_alternating_file_names
+ )
+ epytest
+}
+
+python_install_all() {
+ rm -r doc/build || die
+
+ use doc && local HTML_DOCS=( doc/. )
+ distutils-r1_python_install_all
+}