summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2024-05-15 03:54:22 +0200
committerMichał Górny <mgorny@gentoo.org>2024-05-15 04:01:23 +0200
commit0366cea8ecb43c642ba39ffb78fe99e65910048c (patch)
treeed4ec46da47beb6bc6d8ea9def2dd58ba4e0547f /dev-python/mako/mako-1.3.5.ebuild
parentdev-python/scikit-build-core: Bump to 0.9.4 (diff)
downloadgentoo-0366cea8ecb43c642ba39ffb78fe99e65910048c.tar.gz
gentoo-0366cea8ecb43c642ba39ffb78fe99e65910048c.tar.bz2
gentoo-0366cea8ecb43c642ba39ffb78fe99e65910048c.zip
dev-python/mako: Bump to 1.3.5
Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'dev-python/mako/mako-1.3.5.ebuild')
-rw-r--r--dev-python/mako/mako-1.3.5.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/mako/mako-1.3.5.ebuild b/dev-python/mako/mako-1.3.5.ebuild
new file mode 100644
index 000000000000..3203b0011bc2
--- /dev/null
+++ b/dev-python/mako/mako-1.3.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="
+ https://www.makotemplates.org/
+ https://github.com/sqlalchemy/mako/
+ https://pypi.org/project/Mako/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+RDEPEND="
+ >=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/Babel[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=()
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ test/test_exceptions.py::ExceptionsTest::test_alternating_file_names
+ )
+ ;;
+ esac
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
+
+python_install_all() {
+ rm -r doc/build || die
+
+ use doc && local HTML_DOCS=( doc/. )
+ distutils-r1_python_install_all
+}