summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLouis Sautier <sbraz@gentoo.org>2020-04-20 22:34:47 +0200
committerLouis Sautier <sbraz@gentoo.org>2020-04-20 23:00:00 +0200
commitf92155f2fc5db0e754d11d343485a93700ffb601 (patch)
tree9e90da3c9edd972f38d8b3256f03764ce8c89af6 /dev-python/pushbullet-py
parentdev-python/python-magic: add Python 3.8 support (diff)
downloadgentoo-f92155f2fc5db0e754d11d343485a93700ffb601.tar.gz
gentoo-f92155f2fc5db0e754d11d343485a93700ffb601.tar.bz2
gentoo-f92155f2fc5db0e754d11d343485a93700ffb601.zip
dev-python/pushbullet-py: support Python 3.7, 3.8 and PyPy3, EAPI=7
Package-Manager: Portage-2.3.96, Repoman-2.3.22 Signed-off-by: Louis Sautier <sbraz@gentoo.org>
Diffstat (limited to 'dev-python/pushbullet-py')
-rw-r--r--dev-python/pushbullet-py/pushbullet-py-0.11.0-r1.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/pushbullet-py/pushbullet-py-0.11.0-r1.ebuild b/dev-python/pushbullet-py/pushbullet-py-0.11.0-r1.ebuild
new file mode 100644
index 00000000000..c1adf5146b1
--- /dev/null
+++ b/dev-python/pushbullet-py/pushbullet-py-0.11.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+DESCRIPTION="A simple python client for pushbullet.com"
+HOMEPAGE="https://github.com/randomchars/pushbullet.py"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/python-magic[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ ${RDEPEND}
+ dev-python/pytest[${PYTHON_USEDEP}]
+ )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_test() {
+ # skip tests which require network access
+ PUSHBULLET_API_KEY= pytest -vv \
+ -k "not (test_auth or test_decryption)" \
+ || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r example/.
+ fi
+ distutils-r1_python_install_all
+}