summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2020-04-18 16:18:48 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2020-04-18 21:32:47 +0200
commit3f9f8015625094a1a9fa13495a7ee2948c6b036e (patch)
tree981226eae2339317137bbfea3d4add5f835df7df /dev-python/tagpy
parentdev-lang/go: remove 1.14.1 (diff)
downloadgentoo-3f9f8015625094a1a9fa13495a7ee2948c6b036e.tar.gz
gentoo-3f9f8015625094a1a9fa13495a7ee2948c6b036e.tar.bz2
gentoo-3f9f8015625094a1a9fa13495a7ee2948c6b036e.zip
dev-python/tagpy: python3_8 support
Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-python/tagpy')
-rw-r--r--dev-python/tagpy/tagpy-2018.1-r1.ebuild49
1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/tagpy/tagpy-2018.1-r1.ebuild b/dev-python/tagpy/tagpy-2018.1-r1.ebuild
new file mode 100644
index 00000000000..46c43febbef
--- /dev/null
+++ b/dev-python/tagpy/tagpy-2018.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_IN_SOURCE_BUILD=1
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+DESCRIPTION="Python Bindings for TagLib"
+HOMEPAGE="https://mathema.tician.de//software/tagpy
+ https://pypi.org/project/tagpy/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 ~sparc x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-libs/boost-1.70:=[python,threads,${PYTHON_USEDEP}]
+ >=media-libs/taglib-1.8
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/${P}-taglib-1.8.patch" )
+
+python_prepare_all() {
+ cp "${FILESDIR}"/${P}-readme.rst README.rst || die
+ distutils-r1_python_prepare_all
+}
+
+python_configure() {
+ local boostpy_ver="${EPYTHON#python}"
+
+ "${PYTHON}" configure.py \
+ --taglib-inc-dir="${EPREFIX}/usr/include/taglib" \
+ --boost-python-libname="boost_python${boostpy_ver/\.}"
+}
+
+python_install_all() {
+ if use examples; then
+ docinto examples
+ dodoc -r test/*
+ fi
+
+ distutils-r1_python_install_all
+}