dev-python/urwid: version bump to 2.1.0

Update to EAPI 7, add py38 support, add use distutils_enable_* funcs
from distutils-r1 eclass for sphinx/test support.

Signed-off-by: Tim Harder <radhermit@gentoo.org>

1 files changed, 35 insertions, 0 deletions

diff --git a/dev-python/urwid/urwid-2.1.0.ebuild b/dev-python/urwid/urwid-2.1.0.ebuild
new file mode 100644
index 000000000000..5685bca7c7f7
--- /dev/null
+++ b/dev-python/urwid/urwid-2.1.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Curses-based user interface library for Python"
+HOMEPAGE="http://urwid.org/ https://pypi.org/project/urwid/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+distutils_enable_sphinx docs
+distutils_enable_tests setup.py
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		export CFLAGS
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}