dev-python/virtualenv: Bump to 20.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 4702e3f6988b..f24f1608ab6f 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-16.7.10.tar.gz 5116776 BLAKE2B 42f0a4b4330850b504f8febd991ef6ecdcbb0821efdd94ca324a8cc34a68a760a8a98de97f0cb2384d8e6cbb0ce8f261995c6433886444e29b75ba0ce09ca12c SHA512 f06d7c354ce1910f04dbcbe1a77e60392653bbe4f638bafbe9284454db2c0e5d63cf9159201d0916fc01aaba91d45fb733b63096c38517fcd83fd00ed8b26d28
 DIST virtualenv-20.0.35.tar.gz 8283086 BLAKE2B 66d6b22d9928bf3925c8911e24fa1ba22d1276518c23e0d951c58cca0cb34f67e5053f27882ab9eafbdba040a893861eadb40497398d9deaacb45c461bfa01cc SHA512 066cefbf9c6c77277a1c97c8cf555a8b4411784ad289c058f107872be15e9dd4ef9ac6e4ec64143e0b30512d9f454408e18e434ef8f9b2bfe3e6456fade71251
+DIST virtualenv-20.1.0.tar.gz 8284462 BLAKE2B 4356c9c49f7bd2dbb6cf8998be5cd3970804bdec5e3c1223439700f4b5597cd843cdb17b722d54f0181094296247d1f2d4c27980679602b94020fdf1e95dd73f SHA512 740bf8ba30d836c240d248dd2fa31a8702cfa8f96a6192dd6430dbeff3ebbf0fe67d4fd2439ed4961869731520b097783a29381eae3f81f6700b6050b75422c8
diff --git a/dev-python/virtualenv/virtualenv-20.1.0.ebuild b/dev-python/virtualenv/virtualenv-20.1.0.ebuild
new file mode 100644
index 000000000000..a734981f18b9
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.1.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-0.12[${PYTHON_USEDEP}]
+	' python3_{6,7} pypy3)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.0[${PYTHON_USEDEP}]
+	' python3_6 pypy3)"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/coverage[${PYTHON_USEDEP}]
+			dev-python/flaky[${PYTHON_USEDEP}]
+			>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+			>=dev-python/pytest-5[${PYTHON_USEDEP}]
+			>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+			>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+			>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+		' 'python3*')
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+
+src_prepare() {
+	# we don't have xonsh
+	rm tests/unit/activation/test_xonsh.py || die
+	# require internet
+	sed -e 's:test_seed_link_via_app_data:_&:' \
+		-i tests/unit/seed/embed/test_boostrap_link_via_app_data.py || die
+	# TODO: investigate
+	sed -e 's:test_cross_major:_&:' \
+		-i tests/unit/create/test_creator.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	if [[ ${EPYTHON} == pypy3 ]]; then
+		# TODO: skip with better granularity
+		ewarn "Skipping broken tests on pypy3"
+		return
+	fi
+
+	distutils_install_for_testing
+
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}