dev-util/d-feet: bump to 0.3.14

Includes various ebuild simplifications and fixes:
* UPDATE_DESKTOP avoidance not needed, upstream has had a DESTDIR
  check in there for a while now.
* 0.3.14 moved from pep8 to preferring the new name of pycodestyle;
  instead of updating the sed, just add the dependency now, as the
  whitespace tests actually pass upstream now, unlike in 0.3.13.
* Downgrade dep from yelp-tools to itstool, as we don't call eautoreconf
* Fix LICENSE to have or-later
* Remove error throwing python_fix_shebang call - not sure why it
  errors now on not finding anything to fix, but at least in 0.3.14
  it's unnecessary anyways, as $PYTHON from ebuild env is properly
  honored and the relevant shebangs are correct without any manual
  fixing.

Closes: https://bugs.gentoo.org/678768
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-util/d-feet/d-feet-0.3.14.ebuild b/dev-util/d-feet/d-feet-0.3.14.ebuild
new file mode 100644
index 00000000000..af1ae4c4c6d
--- /dev/null
+++ b/dev-util/d-feet/d-feet-0.3.14.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1 virtualx
+
+DESCRIPTION="D-Feet is a powerful D-Bus debugger"
+HOMEPAGE="https://wiki.gnome.org/Apps/DFeet"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="test +X"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.9.4:3[introspection]
+	>=dev-libs/gobject-introspection-0.9.6:=
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=dev-libs/glib-2.34:2
+	>=dev-python/pygobject-3.3.91:3[${PYTHON_USEDEP}]
+	>=sys-apps/dbus-1
+	X? ( x11-libs/libwnck:3[introspection] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	dev-util/itstool
+	>=dev-util/intltool-0.40.0
+	test? ( dev-python/pycodestyle )
+" # eautoreconf needs yelp-tools
+
+src_configure() {
+	# Tests are only python pep8 whitespace checking and intltool checks - checking python whitespate style is not useful for us
+	gnome2_src_configure \
+		$(use_enable test tests)
+}
+
+src_test() {
+	virtx default
+}