summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNils Freydank <holgersson@posteo.de>2018-03-25 20:18:51 +0200
committerDavide Pesavento <pesa@gentoo.org>2018-03-25 20:19:48 +0200
commit79ebba66327d5a16eaff68aab7567efb695db6c0 (patch)
tree39c03bdad49c95e2ccf2409262f21e02f328f2f5 /dev-util/eric
parentdev-util/eric: add (+) on qscintilla-python[qt5] USE dep (diff)
downloadgentoo-79ebba66327d5a16eaff68aab7567efb695db6c0.tar.gz
gentoo-79ebba66327d5a16eaff68aab7567efb695db6c0.tar.bz2
gentoo-79ebba66327d5a16eaff68aab7567efb695db6c0.zip
dev-util/eric: Bump to 18.03.
Closes: https://github.com/gentoo/gentoo/pull/7564 Package-Manager: Portage-2.3.24, Repoman-2.3.6
Diffstat (limited to 'dev-util/eric')
-rw-r--r--dev-util/eric/Manifest1
-rw-r--r--dev-util/eric/eric-18.03.ebuild78
2 files changed, 79 insertions, 0 deletions
diff --git a/dev-util/eric/Manifest b/dev-util/eric/Manifest
index 9df3e3a5471..d34fd881907 100644
--- a/dev-util/eric/Manifest
+++ b/dev-util/eric/Manifest
@@ -1 +1,2 @@
DIST eric6-17.12.tar.gz 19035763 BLAKE2B e19195ef0b36ce216dc4f21ec221da4002a20ee3e3e300b80045d31d8793df299c2224f41f562fb59a0f8a65ead4f616df89a905905918dd1ae396d55d77fdc3 SHA512 7144c1fad76eb0f3ccdd2a29fb3fc369ad35d28dfbae1e6b75855b85218df34afa715f3a2df37bd6163e2f3a23a2a9a7f528cfe54f1bc21486ab81da6a69a697
+DIST eric6-18.03.tar.gz 16517664 BLAKE2B f7f5292df8bc694fc4715ec1a250d948123a2eb99a590e6824d985318446babff86aeb745f5b5dbd0707e771638eaa943673e5b546676bea97e266888b844989 SHA512 e488010791b44cc7da782620baec9b97259aaefeb90d491023ec1d4582fb68acbc06d9eedba7beef9ddc706302e06e36b9ebb4e46d6f035b6c74e9f4eb9ac400
diff --git a/dev-util/eric/eric-18.03.ebuild b/dev-util/eric/eric-18.03.ebuild
new file mode 100644
index 00000000000..270355f4d0c
--- /dev/null
+++ b/dev-util/eric/eric-18.03.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P=${PN}6-${PV}
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite,xml"
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="https://eric-ide.python-projects.org/"
+SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="6"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+ ${PYTHON_DEPS}
+ >=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
+ >=dev-python/PyQt5-5.7.1[gui,network,printsupport,sql,svg,widgets,${PYTHON_USEDEP}]
+ >=dev-python/qscintilla-python-2.10[qt5(+),${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+ || (
+ dev-python/PyQt5[help,webengine,${PYTHON_USEDEP}]
+ dev-python/PyQt5[help,webkit,${PYTHON_USEDEP}]
+ )
+ >=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+ >=dev-python/coverage-4.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.2.0[${PYTHON_USEDEP}]
+ !dev-util/eric:4
+ !dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( changelog README.rst THANKS )
+
+src_prepare() {
+ default
+
+ # Delete internal copies of dev-python/chardet and dev-python/pygments
+ rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+ # Delete internal copy of dev-python/coverage
+ rm -fr eric/DebugClients/Python{,3}/coverage || die
+ sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+ $(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+}
+
+src_install() {
+ "${PYTHON}" install.py \
+ -b "${EPREFIX}/usr/bin" \
+ -d "$(python_get_sitedir)" \
+ -i "${D}" \
+ -c \
+ -z \
+ || die
+
+ python_optimize
+ einstalldocs
+}
+
+pkg_postinst(){
+ xdg_desktop_database_update
+
+ if ! has_version dev-python/enchant; then
+ elog "You might want to install dev-python/pyenchant for spell checking."
+ fi
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}