summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMike Gilbert <floppym@gentoo.org>2018-10-08 12:23:49 -0400
committerMike Gilbert <floppym@gentoo.org>2018-10-08 12:24:21 -0400
commit364d527015bfeca046ddbc055b3740127b098b59 (patch)
tree51340fbe7738d42af5604de2268e051de141066e /dev-util/ninja
parentdev-python/ebuildtester: Drop old versions (diff)
downloadgentoo-364d527015bfeca046ddbc055b3740127b098b59.tar.gz
gentoo-364d527015bfeca046ddbc055b3740127b098b59.tar.bz2
gentoo-364d527015bfeca046ddbc055b3740127b098b59.zip
dev-util/ninja: add new kitware release (1.8.2.g81279)
Closes: https://bugs.gentoo.org/667952 Package-Manager: Portage-2.3.50_p14, Repoman-2.3.11_p21 Signed-off-by: Mike Gilbert <floppym@gentoo.org>
Diffstat (limited to 'dev-util/ninja')
-rw-r--r--dev-util/ninja/Manifest3
-rw-r--r--dev-util/ninja/ninja-1.8.2-r1.ebuild11
-rw-r--r--dev-util/ninja/ninja-1.8.2-r2.ebuild131
3 files changed, 139 insertions, 6 deletions
diff --git a/dev-util/ninja/Manifest b/dev-util/ninja/Manifest
index 15be30523ae..400f6e8bd92 100644
--- a/dev-util/ninja/Manifest
+++ b/dev-util/ninja/Manifest
@@ -1,3 +1,4 @@
DIST ninja-1.7.2.tar.gz 180611 BLAKE2B 9e0b5faaed9dd0c01b3cb22e5927668e985f897c4a448871b3147d4383d562b91f4e4fe304cb61a31d5ee096b58f0c4e4a7c1907ed9637658faa1eafb31cdd72 SHA512 29900d07364d87ad8b9614b82bc1b0afda5ca6522563ab73fb228f206ed6b29b70cf034a3caf5a9b2c0b105d1e076c6b425d93b5d14aa3ca3730d75611212a64
-DIST ninja-1.8.2-fortran.tar.gz 203848 BLAKE2B a6002abcfe4003dd5c9ccb8fd504b98736a6bc249323ca7afabc042a5091b9e7f0c0c19853cd7a270e00b0825ea14a7ba47c1b35d15f725c7b4866de1a79c07a SHA512 74f42181a2a712653450b0ab7ce5ad93b5ec010f4ab8411c732f682be5a6a991a7481ae1649ad70a7b903c45427b1e238b001aef29702f0896a1ae393ee22bec
+DIST ninja-1.8.2.g3bbbe.kitware.dyndep-1.jobserver-1.tar.gz 203848 BLAKE2B a6002abcfe4003dd5c9ccb8fd504b98736a6bc249323ca7afabc042a5091b9e7f0c0c19853cd7a270e00b0825ea14a7ba47c1b35d15f725c7b4866de1a79c07a SHA512 74f42181a2a712653450b0ab7ce5ad93b5ec010f4ab8411c732f682be5a6a991a7481ae1649ad70a7b903c45427b1e238b001aef29702f0896a1ae393ee22bec
+DIST ninja-1.8.2.g81279.kitware.dyndep-1.jobserver-1.tar.gz 204539 BLAKE2B cee66a5d6ad7fd1254e68cf7be1e97eb796ec3103bdb9e869dc66757a96ce1d6e946018aa048855e70d6a3698ae609f75740809a8e9183057da16769f07e1fa6 SHA512 ae5f9c4c76114cabc4ec06056edccfa4027d514c4ae0f3ab08bbcd3ce2322e9ff08b8f90fe69fab989707adb6ecc78f226b65e223b41535aa5c0db5b6c61117a
DIST ninja-1.8.2.tar.gz 185226 BLAKE2B c464c50829a0e9f0f6fd4b860946b14bf07f752adb8e7857d4072a1c1f06977eda283f633041929065c9164377ca769b3293b04fc9ceab583371708a9c4e8f2a SHA512 1650bf9e3eddeb0b0fbb415c2b8e0a7c094421e991fa8139fd77fae0f6ee7ee980b7cf5e98d883c3a884f99abcb06fa26e3980af3a3a5bb6dd655124755782c2
diff --git a/dev-util/ninja/ninja-1.8.2-r1.ebuild b/dev-util/ninja/ninja-1.8.2-r1.ebuild
index caa2bb8e646..84c7f67ce66 100644
--- a/dev-util/ninja/ninja-1.8.2-r1.ebuild
+++ b/dev-util/ninja/ninja-1.8.2-r1.ebuild
@@ -1,17 +1,20 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
-inherit bash-completion-r1 elisp-common python-any-r1 toolchain-funcs vcs-snapshot
+inherit bash-completion-r1 elisp-common python-any-r1 toolchain-funcs
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/ninja-build/ninja.git"
else
- SRC_URI="https://github.com/Kitware/${PN}/archive/v${PV}.g3bbbe.kitware.dyndep-1.jobserver-1.tar.gz -> ${P}-fortran.tar.gz"
+ KITWARE_VERSION="1.8.2.g3bbbe.kitware.dyndep-1.jobserver-1"
+ MY_P="ninja-${KITWARE_VERSION}"
+ S="${WORKDIR}/${MY_P}"
+ SRC_URI="https://github.com/Kitware/ninja/archive/v${KITWARE_VERSION}.tar.gz -> ${MY_P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
fi
@@ -44,8 +47,6 @@ RDEPEND="
zsh-completion? ( app-shells/zsh )
!<net-irc/ninja-1.5.9_pre14-r1" #436804
-S="${WORKDIR}/${P}-fortran"
-
run_for_build() {
if tc-is-cross-compiler; then
local -x AR=$(tc-getBUILD_AR)
diff --git a/dev-util/ninja/ninja-1.8.2-r2.ebuild b/dev-util/ninja/ninja-1.8.2-r2.ebuild
new file mode 100644
index 00000000000..18d8f1000a7
--- /dev/null
+++ b/dev-util/ninja/ninja-1.8.2-r2.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 elisp-common python-any-r1 toolchain-funcs
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/ninja-build/ninja.git"
+else
+ KITWARE_VERSION="1.8.2.g81279.kitware.dyndep-1.jobserver-1"
+ MY_P="ninja-${KITWARE_VERSION}"
+ S="${WORKDIR}/${MY_P}"
+ SRC_URI="https://github.com/Kitware/ninja/archive/v${KITWARE_VERSION}.tar.gz -> ${MY_P}.tar.gz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+fi
+
+DESCRIPTION="A small build system similar to make"
+HOMEPAGE="https://ninja-build.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+IUSE="doc emacs test vim-syntax zsh-completion"
+
+DEPEND="
+ ${PYTHON_DEPS}
+ dev-util/re2c
+ doc? (
+ app-text/asciidoc
+ app-doc/doxygen
+ dev-libs/libxslt
+ )
+ test? ( dev-cpp/gtest )
+"
+RDEPEND="
+ emacs? ( virtual/emacs )
+ vim-syntax? (
+ || (
+ app-editors/vim
+ app-editors/gvim
+ )
+ )
+ zsh-completion? ( app-shells/zsh )
+ !<net-irc/ninja-1.5.9_pre14-r1" #436804
+
+run_for_build() {
+ if tc-is-cross-compiler; then
+ local -x AR=$(tc-getBUILD_AR)
+ local -x CXX=$(tc-getBUILD_CXX)
+ local -x CFLAGS=${BUILD_CXXFLAGS}
+ local -x LDFLAGS=${BUILD_LDFLAGS}
+ fi
+ "$@"
+}
+
+src_compile() {
+ tc-export AR CXX
+
+ # configure.py uses CFLAGS instead of CXXFLAGS
+ export CFLAGS=${CXXFLAGS}
+
+ run_for_build "${PYTHON}" configure.py --bootstrap --verbose || die
+
+ if tc-is-cross-compiler; then
+ mv ninja ninja-build || die
+ "${PYTHON}" configure.py || die
+ ./ninja-build -v ninja || die
+ else
+ ln ninja ninja-build || die
+ fi
+
+ if use doc; then
+ ./ninja-build -v doxygen manual || die
+ fi
+
+ if use emacs; then
+ elisp-compile misc/ninja-mode.el || die
+ fi
+}
+
+src_test() {
+ if ! tc-is-cross-compiler; then
+ # Bug 485772
+ ulimit -n 2048
+ ./ninja-build -v ninja_test || die
+ ./ninja_test || die
+ fi
+}
+
+src_install() {
+ dodoc README HACKING.md
+ if use doc; then
+ docinto html
+ dodoc -r doc/doxygen/html/.
+ dodoc doc/manual.html
+ fi
+ dobin ninja
+
+ newbashcomp misc/bash-completion "${PN}"
+
+ if use vim-syntax; then
+ insinto /usr/share/vim/vimfiles/syntax/
+ doins misc/"${PN}".vim
+
+ echo 'au BufNewFile,BufRead *.ninja set ft=ninja' > "${T}/${PN}.vim"
+ insinto /usr/share/vim/vimfiles/ftdetect
+ doins "${T}/${PN}.vim"
+ fi
+
+ if use zsh-completion; then
+ insinto /usr/share/zsh/site-functions
+ newins misc/zsh-completion _ninja
+ fi
+
+ if use emacs; then
+ cd misc || die
+ elisp-install ${PN} ninja-mode.el* || die
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}