summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2021-05-09 11:02:52 +0200
committerMichał Górny <mgorny@gentoo.org>2021-05-09 11:13:19 +0200
commit20f30c3568750f4a818ef653be4036b0dca927f5 (patch)
tree87984a102e94789701c84811c5674f88b52d4bfd /dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild
parentsys-fs/lvm2: Bump to version 2.03.12. Removed old (diff)
downloadgentoo-20f30c3568750f4a818ef653be4036b0dca927f5.tar.gz
gentoo-20f30c3568750f4a818ef653be4036b0dca927f5.tar.bz2
gentoo-20f30c3568750f4a818ef653be4036b0dca927f5.zip
dev-util/pkgcheck: Fix PythonCompatUpdate handling of py3.10
Fix PythonCompatUpdate check to treat python3.10 as newer than 3.9. Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild')
-rw-r--r--dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild63
1 files changed, 63 insertions, 0 deletions
diff --git a/dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild b/dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild
new file mode 100644
index 000000000000..1859af4de531
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-0.9.7-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+ EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
+ inherit git-r3
+else
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="pkgcore-based QA utility for ebuild repos"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="BSD MIT"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+ RDEPEND="
+ ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+ ~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+ RDEPEND="
+ >=dev-python/snakeoil-0.9.6[${PYTHON_USEDEP}]
+ >=sys-apps/pkgcore-0.11.6[${PYTHON_USEDEP}]"
+fi
+RDEPEND+="
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/pathspec[${PYTHON_USEDEP}]
+ >=dev-python/tree-sitter-0.19.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests setup.py
+
+PATCHES=(
+ "${FILESDIR}"/${P}-py310-update.patch
+)
+
+src_test() {
+ local -x PYTHONDONTWRITEBYTECODE=
+ distutils-r1_src_test
+}
+
+python_install_all() {
+ local DOCS=( NEWS.rst )
+ [[ ${PV} == *9999 ]] || doman man/*
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Network check support" dev-python/requests
+ optfeature "Perl module version check support" dev-perl/Gentoo-PerlMod-Version
+}