summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorLars Wendler <polynomial-c@gentoo.org>2017-11-30 00:28:04 +0100
committerLars Wendler <polynomial-c@gentoo.org>2017-11-30 00:38:27 +0100
commit3a99274f5b95c9046eadd8a68f1640ac8da4b3f4 (patch)
tree3459cf91c4923dcffab114fd68c0c2e8cf7e407f /dev-vcs
parentwww-plugins/chrome-binary-plugins: automated update (63.0.3239.70, 64.0.3278.0) (diff)
downloadgentoo-3a99274f5b95c9046eadd8a68f1640ac8da4b3f4.tar.gz
gentoo-3a99274f5b95c9046eadd8a68f1640ac8da4b3f4.tar.bz2
gentoo-3a99274f5b95c9046eadd8a68f1640ac8da4b3f4.zip
dev-vcs/tortoisehg: Bump to version 4.4.1
Package-Manager: Portage-2.3.16, Repoman-2.3.6
Diffstat (limited to 'dev-vcs')
-rw-r--r--dev-vcs/tortoisehg/Manifest1
-rw-r--r--dev-vcs/tortoisehg/tortoisehg-4.4.1.ebuild80
2 files changed, 81 insertions, 0 deletions
diff --git a/dev-vcs/tortoisehg/Manifest b/dev-vcs/tortoisehg/Manifest
index 56ce4214209..f3e6c033a61 100644
--- a/dev-vcs/tortoisehg/Manifest
+++ b/dev-vcs/tortoisehg/Manifest
@@ -1 +1,2 @@
DIST tortoisehg-4.3.1.tar.gz 7930491 SHA256 5698db60320574769c73e4f910909e75a8e32ba84adcea902f9457899bbcb753 SHA512 dc43f2acd780a7868b642d6ce8a8dbf8f32be94134ddbb72178d7f1eab1e9f58c8e9bcfc75ad589ec9404cabefd9ccfc697af9ccd037c20bd933ee862e812f99 WHIRLPOOL 0275b5d2d76483559d829a6c32b8888af2134fc58367407ff670da21a8d0ae5d98815410520955f41e227af1eb55dd37052af19534756f49d9cb09a91b441de1
+DIST tortoisehg-4.4.1.tar.gz 7923557 BLAKE2B b2574bb87693a3fb824c3c02424b8f5828c1e3673b111ae82ff0692588083eec639a67b200ce6e3def58e5a0e021898c3df62a053fa61d477f92d4226d3a1b69 SHA512 b364e6d16845c03aacaf691e8528e0bd87151026f9f55bcaf61ba67d1eebfc3f9935457e5ca3391e29417682367b9b33803a9870817c22db31f1dd26850e9d53
diff --git a/dev-vcs/tortoisehg/tortoisehg-4.4.1.ebuild b/dev-vcs/tortoisehg/tortoisehg-4.4.1.ebuild
new file mode 100644
index 00000000000..809f95e7806
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-4.4.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != *9999* ]]; then
+ KEYWORDS="~amd64 ~x86"
+ SRC_URI="https://www.bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
+ HG_DEPEND=">=dev-vcs/mercurial-4.3 <dev-vcs/mercurial-4.5"
+else
+ inherit mercurial
+ EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+ EHG_REVISION="stable"
+ HG_DEPEND="dev-vcs/mercurial"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="${HG_DEPEND}
+ dev-python/iniparse[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/PyQt4[svg,${PYTHON_USEDEP}]
+ dev-python/qscintilla-python[qt4(+),${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+ doc? ( >=dev-python/sphinx-1.0.3 )"
+
+# Workaround race condition in build_qt
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+ if [[ ${LINGUAS+set} ]]; then
+ cd i18n/tortoisehg || die
+ local x y keep
+ for x in *.po; do
+ keep=false
+ for y in ${LINGUAS}; do
+ if [[ ${y} == ${x%.po}* ]]; then
+ keep=true
+ break
+ fi
+ done
+ ${keep} || rm "${x}" || die
+ done
+ cd "${S}" || die
+ fi
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ use doc && emake -C doc html
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+ if use doc ; then
+ docinto html
+ dodoc -r doc/build/html/
+ fi
+ newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+ domenu contrib/thg.desktop
+
+ # Remove file that collides with >=mercurial-4.0 (bug #599266).
+ rm "${ED}"/usr/$(get_libdir)/${EPYTHON}/site-packages/hgext3rd/__init__.py \
+ || die
+}
+
+pkg_postinst() {
+ elog "When startup of ${PN} fails with an API version mismatch error"
+ elog "between dev-python/sip and dev-python/PyQt4 please rebuild"
+ elog "dev-python/qscintilla-python."
+}