summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2021-04-04 00:42:25 +0000
committerSam James <sam@gentoo.org>2021-04-04 06:32:34 +0000
commitd6dfb128d98288dbf9d8b2a1be24cf1acb766e36 (patch)
treefecc2d6c4c283cbcb68cffa52ba7c9d75a4757b4 /games-arcade/betna/betna-0.9.7-r1.ebuild
parentgames-arcade/bomns: port to EAPI 7, games.eclass-- (diff)
downloadgentoo-d6dfb128d98288dbf9d8b2a1be24cf1acb766e36.tar.gz
gentoo-d6dfb128d98288dbf9d8b2a1be24cf1acb766e36.tar.bz2
gentoo-d6dfb128d98288dbf9d8b2a1be24cf1acb766e36.zip
games-arcade/betna: port to EAPI 7, games.eclass--
Signed-off-by: Sam James <sam@gentoo.org>
Diffstat (limited to 'games-arcade/betna/betna-0.9.7-r1.ebuild')
-rw-r--r--games-arcade/betna/betna-0.9.7-r1.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/games-arcade/betna/betna-0.9.7-r1.ebuild b/games-arcade/betna/betna-0.9.7-r1.ebuild
new file mode 100644
index 00000000000..0aaf6590200
--- /dev/null
+++ b/games-arcade/betna/betna-0.9.7-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Defend your volcano from the attacking ants by firing rocks/bullets at them"
+HOMEPAGE="http://koti.mbnet.fi/makegho/c/betna/"
+SRC_URI="http://koti.mbnet.fi/makegho/c/betna/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="media-libs/libsdl[video]"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e '/blobprintf.*char msg/s/char msg/const char msg/' \
+ -e "s:images/:/var/lib/${PN}/:" \
+ src/main.cpp || die
+
+ sed -i \
+ -e '/^LDFLAGS/d' \
+ -e '/--libs/s/-o/$(LDFLAGS) -o/' \
+ -e 's:-O2:$(CXXFLAGS):g' \
+ -e 's/g++/$(CXX)/' \
+ Makefile || die
+}
+
+src_configure() {
+ tc-export CXX
+}
+
+src_compile() {
+ emake clean
+ emake
+}
+
+src_install() {
+ dobin betna
+ dodoc README Q\&A
+
+ insinto /var/lib/${PN}
+ doins images/*
+
+ newicon images/target.bmp ${PN}.bmp
+
+ make_desktop_entry ${PN} Betna /usr/share/pixmaps/${PN}.bmp
+}