summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorPacho Ramos <pacho@gentoo.org>2018-04-17 22:57:14 +0200
committerPacho Ramos <pacho@gentoo.org>2018-04-17 23:00:54 +0200
commit57ed97f3867b720855075cce0b26e142455d35d0 (patch)
treed4da9305e81b97f12a9298605c9d91e256fcc0f0 /games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild
parentgames-arcade/kajaani-kombat: Drop old (diff)
downloadgentoo-57ed97f3867b720855075cce0b26e142455d35d0.tar.gz
gentoo-57ed97f3867b720855075cce0b26e142455d35d0.tar.bz2
gentoo-57ed97f3867b720855075cce0b26e142455d35d0.zip
games-arcade/kobodeluxe: Stop using games.eclass
Package-Manager: Portage-2.3.28, Repoman-2.3.9
Diffstat (limited to 'games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild')
-rw-r--r--games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild b/games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild
new file mode 100644
index 00000000000..846176da162
--- /dev/null
+++ b/games-arcade/kobodeluxe/kobodeluxe-0.5.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit desktop
+
+MY_P="KoboDeluxe-${PV/_/}"
+DESCRIPTION="An SDL port of xkobo, a addictive space shoot-em-up"
+HOMEPAGE="http://www.olofson.net/kobodl/"
+SRC_URI="http://www.olofson.net/kobodl/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc64 ~x86"
+IUSE="opengl"
+
+DEPEND="media-libs/libsdl
+ media-libs/sdl-image[png]
+ opengl? ( virtual/opengl )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+ unpack ${A}
+ cd "${S}"
+ unpack ./icons.tar.gz
+}
+
+src_prepare() {
+ default
+ eapply \
+ "${FILESDIR}"/${P}-glibc29.patch \
+ "${FILESDIR}"/${P}-glibc2.10.patch
+ # Fix paths
+ sed -i \
+ -e 's:\$(datadir)/kobo-deluxe:$(datadir)/kobodeluxe:' \
+ -e 's:\$(sharedstatedir)/kobo-deluxe/scores:$(localstatedir)/kobodeluxe:' \
+ configure || die "sed configure failed"
+ sed -i \
+ -e 's:kobo-deluxe:kobodeluxe:' \
+ data/gfx/Makefile.in \
+ data/sfx/Makefile.in || die "sed data/Makefile.in failed"
+}
+
+src_configure() {
+ econf $(use_enable opengl)
+}
+
+src_install () {
+ default
+ newicon icons/KDE/icons/32x32/kobodl.png ${PN}.png
+ make_desktop_entry kobodl "Kobo Deluxe"
+ keepdir /var/lib/${PN}
+}