summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichael Sterrett <mr_bones_@gentoo.org>2015-12-29 10:47:53 -0500
committerMichael Sterrett <mr_bones_@gentoo.org>2015-12-29 10:53:44 -0500
commit0ddb9fcbec1c779051df973a3d4a08821fb42b83 (patch)
treeb48d7bb13fc8807aa0eade4a0e057873d04023eb /games-emulation/mednafen/mednafen-0.9.38.7.ebuild
parentnet-irc/ngircd: bump to vn. ngircd-23 (diff)
downloadgentoo-0ddb9fcbec1c779051df973a3d4a08821fb42b83.tar.gz
gentoo-0ddb9fcbec1c779051df973a3d4a08821fb42b83.tar.bz2
gentoo-0ddb9fcbec1c779051df973a3d4a08821fb42b83.zip
games-emulation/mednafen: version bump
Package-Manager: portage-2.2.24
Diffstat (limited to 'games-emulation/mednafen/mednafen-0.9.38.7.ebuild')
-rw-r--r--games-emulation/mednafen/mednafen-0.9.38.7.ebuild68
1 files changed, 68 insertions, 0 deletions
diff --git a/games-emulation/mednafen/mednafen-0.9.38.7.ebuild b/games-emulation/mednafen/mednafen-0.9.38.7.ebuild
new file mode 100644
index 00000000000..025d9ca6a0d
--- /dev/null
+++ b/games-emulation/mednafen/mednafen-0.9.38.7.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils flag-o-matic pax-utils games
+
+DESCRIPTION="An advanced NES, GB/GBC/GBA, TurboGrafx 16/CD, NGPC and Lynx emulator"
+HOMEPAGE="http://mednafen.fobby.net/"
+SRC_URI="http://mednafen.fobby.net/releases/files/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa altivec cjk debugger jack nls pax_kernel"
+
+RDEPEND="virtual/opengl
+ media-libs/libsndfile
+ dev-libs/libcdio
+ media-libs/libsdl[sound,joystick,opengl,video]
+ media-libs/sdl-net
+ sys-libs/zlib[minizip]
+ alsa? ( media-libs/alsa-lib )
+ jack? ( media-sound/jack-audio-connection-kit )
+ nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}/${PN}
+
+pkg_pretend() {
+ if has ccache ${FEATURES} ; then
+ ewarn
+ ewarn "If you experience build failure, try turning off ccache in FEATURES."
+ ewarn
+ fi
+}
+
+src_prepare() {
+ epatch \
+ "${FILESDIR}"/${P}-localedir.patch \
+ "${FILESDIR}"/${P}-zlib.patch \
+ "${FILESDIR}"/${P}-cflags.patch
+ eautoreconf
+}
+
+src_configure() {
+ # very sensitive code (bug #539992)
+ strip-flags
+ append-flags -fomit-frame-pointer -fwrapv
+ egamesconf \
+ $(use_enable alsa) \
+ $(use_enable altivec) \
+ $(use_enable cjk cjk-fonts) \
+ $(use_enable debugger) \
+ $(use_enable jack) \
+ $(use_enable nls)
+}
+
+src_install() {
+ DOCS="Documentation/cheats.txt ChangeLog TODO" \
+ default
+ if use pax_kernel; then
+ pax-mark m "${D}${GAMES_BINDIR}"/mednafen || die
+ fi
+ prepgamesdirs
+}