summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAustin English <wizardedit@gentoo.org>2017-02-06 18:50:33 -0600
committerAustin English <wizardedit@gentoo.org>2017-02-06 18:51:27 -0600
commit00e629e08d3634bf51c2fbcf11eda0026be3bf23 (patch)
treee47767053ab3c2d4acc388e8387808985a084e10 /games-fps
parentgames-fps/legends: remove deprecated games eclass (diff)
downloadgentoo-00e629e08d3634bf51c2fbcf11eda0026be3bf23.tar.gz
gentoo-00e629e08d3634bf51c2fbcf11eda0026be3bf23.tar.bz2
gentoo-00e629e08d3634bf51c2fbcf11eda0026be3bf23.zip
games-fps/nexuiz: remove deprecated games eclass
Also update to EAPI 6 Gentoo-Bug: https://bugs.gentoo.org/574082 Package-Manager: Portage-2.3.2, Repoman-2.3.1
Diffstat (limited to 'games-fps')
-rw-r--r--games-fps/nexuiz/nexuiz-2.5.2-r1.ebuild137
1 files changed, 137 insertions, 0 deletions
diff --git a/games-fps/nexuiz/nexuiz-2.5.2-r1.ebuild b/games-fps/nexuiz/nexuiz-2.5.2-r1.ebuild
new file mode 100644
index 00000000000..6e290662e3f
--- /dev/null
+++ b/games-fps/nexuiz/nexuiz-2.5.2-r1.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+MY_PN=Nexuiz
+MY_P=${PN}-${PV//./}
+MAPS=nexmappack_r2
+DESCRIPTION="Deathmatch FPS based on DarkPlaces, an advanced Quake 1 engine"
+HOMEPAGE="http://www.nexuiz.com/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip
+ maps? ( mirror://sourceforge/${PN}/${MAPS}.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dedicated maps opengl sdl"
+
+# no headers for libpng needed
+UIRDEPEND="
+ media-libs/libmodplug
+ media-libs/libogg
+ >=media-libs/libpng-1.4:0
+ media-libs/libtheora
+ media-libs/libvorbis
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-libs/libXdmcp
+ x11-libs/libXext
+ x11-libs/libXpm
+ x11-libs/libXxf86dga
+ x11-libs/libXxf86vm
+ virtual/opengl
+ alsa? ( media-libs/alsa-lib )
+ sdl? ( media-libs/libsdl[joystick,opengl,video] )"
+UIDEPEND="x11-proto/xextproto
+ x11-proto/xf86dgaproto
+ x11-proto/xf86vidmodeproto
+ x11-proto/xproto"
+RDEPEND="virtual/jpeg:0
+ net-misc/curl
+ opengl? ( ${UIRDEPEND} )
+ !dedicated? ( !opengl? ( ${UIRDEPEND} ) )"
+DEPEND="${RDEPEND}
+ app-arch/unzip
+ opengl? ( ${UIDEPEND} )
+ !dedicated? ( !opengl? ( ${UIDEPEND} ) )"
+
+S=${WORKDIR}/darkplaces
+
+PATCHES=(
+ "${FILESDIR}"/${P}-libpng-1.4.patch
+)
+
+src_unpack() {
+ unpack ${MY_P}.zip
+
+ local f
+ for f in "${MY_PN}"/sources/*.zip ; do
+ unpack ./${f}
+ done
+
+ if use maps ; then
+ cd "${WORKDIR}"/${MY_PN}
+ unpack ${MAPS}.zip
+ fi
+}
+
+src_prepare() {
+ default
+
+ # Make the game automatically look in the correct data directory
+ sed -i \
+ -e "/^CC=/d" \
+ -e "s:-O2:${CFLAGS}:" \
+ -e "/-lm/s:$: ${LDFLAGS}:" \
+ -e '/^STRIP/s/strip/true/' \
+ makefile.inc || die
+
+ sed -i \
+ -e '1i DP_LINK_TO_LIBJPEG=1' \
+ -e "s:ifdef DP_.*:DP_FS_BASEDIR=/usr/share/${PN}\n&:" \
+ makefile || die
+
+ if ! use alsa ; then
+ sed -i \
+ -e "/DEFAULT_SNDAPI/s:ALSA:OSS:" \
+ makefile || die
+ fi
+}
+
+src_compile() {
+ if use opengl || ! use dedicated ; then
+ emake cl-${PN}
+ if use sdl ; then
+ emake sdl-${PN}
+ fi
+ fi
+
+ if use dedicated ; then
+ emake sv-${PN}
+ fi
+}
+
+src_install() {
+ if use opengl || ! use dedicated ; then
+ dobin ${PN}-glx
+ doicon ${PN}.xpm
+ make_desktop_entry ${PN}-glx "Nexuiz (GLX)"
+ if use sdl ; then
+ dobin ${PN}-sdl
+ make_desktop_entry ${PN}-sdl "Nexuiz (SDL)"
+ dosym ${PN}-sdl /usr/bin/${PN}
+ else
+ dosym ${PN}-glx /usr/bin/${PN}
+ fi
+ fi
+
+ if use dedicated ; then
+ dobin ${PN}-dedicated
+ fi
+
+ cd "${WORKDIR}"/${MY_PN} || die
+
+ dodoc Docs/*.txt
+ dodoc -r readme.html Docs
+
+ insinto /usr/share/${PN}
+
+ if use dedicated ; then
+ doins -r server
+ fi
+
+ doins -r data havoc
+}