summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorNP-Hardass <NP-Hardass@gentoo.org>2017-11-12 11:18:55 -0500
committerNP-Hardass <NP-Hardass@gentoo.org>2017-11-12 11:19:12 -0500
commitf31affe85190419c88471a370865995b5aa3eb6c (patch)
treeeec82ec1b445d7e0431aa5b1f5d861252643b4f4 /games-puzzle
parentnet-misc/memcached: 1.5.3-r1 adds seccomp use flag (diff)
downloadgentoo-f31affe85190419c88471a370865995b5aa3eb6c.tar.gz
gentoo-f31affe85190419c88471a370865995b5aa3eb6c.tar.bz2
gentoo-f31affe85190419c88471a370865995b5aa3eb6c.zip
games-puzzle/sgt-puzzles: Bump to 20171029
Bug: https://bugs.gentoo.org/637120 Package-Manager: Portage-2.3.13, Repoman-2.3.4
Diffstat (limited to 'games-puzzle')
-rw-r--r--games-puzzle/sgt-puzzles/Manifest1
-rw-r--r--games-puzzle/sgt-puzzles/sgt-puzzles-20171029.ebuild113
-rw-r--r--games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild2
3 files changed, 115 insertions, 1 deletions
diff --git a/games-puzzle/sgt-puzzles/Manifest b/games-puzzle/sgt-puzzles/Manifest
index 79cac0464ec..a1412e4a9f0 100644
--- a/games-puzzle/sgt-puzzles/Manifest
+++ b/games-puzzle/sgt-puzzles/Manifest
@@ -1,3 +1,4 @@
DIST puzzles-20170314.eedea41.tar.gz 2897824 SHA256 57c156fa7de2605a4ae0f18e54ce20ef4e08b8faf32d26eccf5a7fa545940fa8 SHA512 ef7d12e0e20aef487a18b572a4464f3e23b226fae599cc22fdb34348f6c3baf3dcd21207c8fedef0ac3a6c4344b13e520767efef8830aaa2ad4b914285f8aa3c WHIRLPOOL 17b069ae171497212411ed6696fafd00108064f3a28ce38925a4fc6d9040e3d072a14920b024c329e597fe1fdedc9723089ea5c17d7df9226ac45ba612a1de70
DIST puzzles-20170514.7bdfda8.tar.gz 2910137 SHA256 fa7e0e7d2f4bf43d4d5d91e0836ad87a133657a99f00ec5ee77504cd8bafda58 SHA512 b0acbc1cf3e2986c6c3a58a126ff4e9e8751e93ee9a4771e2fd8af6c98c01bbbe01db8ccc526fdbac1ee8bf9a4391c9b90d66e19458fdc53858a6a3724c02a4b WHIRLPOOL bae1cd85b3d4973db5e8610cb9b023a39fe5ee11386723e44d4ef7464615f9373d5b10f2d8cf325257709b3184ee40453b0262e22e427a8353f0e9c1c74adc51
+DIST puzzles-20171029.69773d8.tar.gz 2923623 SHA256 c075f5b1063a8881ad5efb393595912fdf9f7f016b5fce6082d14b0190522f54 SHA512 ca9885bcadd0bb979167f2f0b6129a17aeab6d7fd31eeabc9d29ab526a5a137b03f1f4aea7a268109c5aee1a522d514bf522ad25673705f50addd685401d7fb8 WHIRLPOOL 4d214667bcfef5f43c62efbe8787e3ce879a780b9886ea3fd7920202d2ee0bbd98622463ffd0d8392248a256198e8f67f674aacacebdec83eae34004f2f688bb
DIST sgt-puzzles-icons-20160315.tar.xz 715536 SHA256 9ddc1b6d02b3c3358a9bc6b17c7070650f794cf5f650f25b2ac7e5def6674447 SHA512 2fe2c02984eb8c36ac6fb4195be7895b336b84f40ce8baeb23dc8a32aca9937ccf1d33050b4da3cfba3c87e124ecbdd940ee4e990b37eabe8e2af897c2e23b57 WHIRLPOOL 17bdadc9519320bc88af27f2db7a9c243f04d80e524db51ad9398831185e2c66f2430006c324fa7d5b70ce156cb9df93d9405216053b32101b5f56035a60f6ac
diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-20171029.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-20171029.ebuild
new file mode 100644
index 00000000000..cc3a64811f1
--- /dev/null
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-20171029.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gnome2-utils toolchain-funcs autotools
+
+if [[ ${PV} == "99999999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="git://git.tartarus.org/simon/puzzles.git"
+ GENTOO_ICONS="20160315"
+ SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
+ KEYWORDS=""
+else
+ MAGIC=69773d8
+ SRC_URI="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
+ S=${WORKDIR}/puzzles-${PV}.${MAGIC}
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
+HOMEPAGE="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+doc gtk3"
+
+COMMON_DEPEND="
+ !gtk3? ( x11-libs/gtk+:2 )
+ gtk3? ( x11-libs/gtk+:3 )"
+
+RDEPEND="${COMMON_DEPEND}
+ x11-misc/xdg-utils" # Used by builtin help patch
+
+DEPEND="${COMMON_DEPEND}
+ dev-lang/perl
+ virtual/pkgconfig
+ doc? ( >=app-doc/halibut-1.2 )"
+
+PATCHES=( "${FILESDIR}/${PN}-20161207-builtin-help.patch" )
+
+src_unpack() {
+ default
+ if [[ ${PV} == "99999999" ]]; then
+ git-r3_src_unpack
+ fi
+}
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e 's/-O2 -Wall -Werror -ansi -pedantic -g//' \
+ -e "s/libstr =/libstr = '\$(LDFLAGS) ' ./" \
+ mkfiles.pl || die
+ ./mkfiles.pl || die
+ eautoreconf
+
+ # Import icons from latest Gentoo tarball for live
+ if [[ ${PV} == "99999999" ]]; then
+ cp -R ../${PN}-icons/icons . || die
+ fi
+}
+
+src_configure() {
+ econf \
+ --program-prefix="${PN}_" \
+ --with-gtk=$(usex gtk3 3 2)
+}
+
+src_compile() {
+ emake CC="$(tc-getCC)"
+ if use doc ; then
+ halibut --text --html --info --pdf --ps puzzles.but || die
+ fi
+}
+
+src_install() {
+ default
+
+ local file name
+ for file in *.R ; do
+ [[ ${file} == "nullgame.R" ]] && continue
+ name=$(awk -F: '/exe:/ { print $3 }' "${file}")
+ file=${file%.R}
+ newicon -s 48 icons/${file}-48d24.png ${PN}_${file}.png
+ make_desktop_entry "${PN}_${file}" "${name}" "${PN}_${file}" "Game;LogicGame;X-${PN};"
+ done
+
+ if use doc ; then
+ DOCS=( puzzles.{pdf,ps,txt} )
+ HTML_DOCS=( *.html )
+ einstalldocs
+ doinfo puzzles.info{,-1,-2,-3}
+ fi
+
+ insinto /etc/xdg/menus/applications-merged
+ doins "${FILESDIR}/${PN}.menu"
+ insinto /usr/share/desktop-directories
+ doins "${FILESDIR}/${PN}.directory"
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+}
diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
index 483e2dc3387..cc3a64811f1 100644
--- a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
@@ -12,7 +12,7 @@ if [[ ${PV} == "99999999" ]] ; then
SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
KEYWORDS=""
else
- MAGIC=7bdfda8
+ MAGIC=69773d8
SRC_URI="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
S=${WORKDIR}/puzzles-${PV}.${MAGIC}
KEYWORDS="~amd64 ~x86"