summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAustin English <wizardedit@gentoo.org>2016-10-15 04:06:16 -0500
committerAustin English <wizardedit@gentoo.org>2016-10-15 05:16:39 -0500
commit337eed8c76386be0311cbeff448f1a4cbccbcdf6 (patch)
tree4df8a407646493a0bbc1b75cdc05b7f70db5df72 /games-rpg/egoboo/egoboo-2.8.1-r1.ebuild
parentgames-rpg/dragonhunt: remove deprecated games eclass (diff)
downloadgentoo-337eed8c76386be0311cbeff448f1a4cbccbcdf6.tar.gz
gentoo-337eed8c76386be0311cbeff448f1a4cbccbcdf6.tar.bz2
gentoo-337eed8c76386be0311cbeff448f1a4cbccbcdf6.zip
games-rpg/egoboo: remove deprecated games eclass
Also update to EAPI 6 Gentoo-Bug: https://bugs.gentoo.org/574082 Package-Manager: portage-2.3.0
Diffstat (limited to 'games-rpg/egoboo/egoboo-2.8.1-r1.ebuild')
-rw-r--r--games-rpg/egoboo/egoboo-2.8.1-r1.ebuild60
1 files changed, 60 insertions, 0 deletions
diff --git a/games-rpg/egoboo/egoboo-2.8.1-r1.ebuild b/games-rpg/egoboo/egoboo-2.8.1-r1.ebuild
new file mode 100644
index 000000000000..4d36a953437d
--- /dev/null
+++ b/games-rpg/egoboo/egoboo-2.8.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="A 3d dungeon crawling adventure in the spirit of NetHack"
+HOMEPAGE="http://egoboo.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="
+ dev-games/physfs
+ media-libs/libsdl[joystick,video]
+ media-libs/sdl-image
+ media-libs/sdl-mixer[vorbis]
+ media-libs/sdl-ttf
+ net-libs/enet:0
+ virtual/glu
+ virtual/opengl"
+RDEPEND=${DEPEND}
+
+PATCHES=(
+ "${FILESDIR}"/${P}-gentoo.patch
+)
+
+src_prepare() {
+ edos2unix src/game/platform/file_linux.c \
+ src/game/network.c \
+ src/game/Makefile
+ default
+ sed -i \
+ -e "s:@GENTOO_CONFDIR@:/etc/${PN}:" \
+ -e "s:@GENTOO_DATADIR@:/usr/share/${PN}:" \
+ src/game/platform/file_linux.c || die "sed failed"
+ rm -rf src/enet || die
+}
+
+src_compile() {
+ emake -C src/game PROJ_NAME=egoboo-2.x
+}
+
+src_install() {
+ dodoc BUGS.txt Changelog.txt doc/*.txt doc/*.pdf
+
+ insinto /usr/share/${PN}
+ doins -r basicdat modules
+ insinto /etc/${PN}
+ doins -r controls.txt setup.txt
+
+ newbin src/game/egoboo-2.x ${PN}
+
+ newicon basicdat/icon.bmp ${PN}.bmp
+ make_desktop_entry ${PN} Egoboo /usr/share/pixmaps/${PN}.bmp
+}