games-simulation/crashtest: EAPI 6->8, plib to RDEPEND, use EPREFIX

Also removed unused alsa-lib, and unused append-cppflags (traded for
a more needed tc-export CXX).

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 44 insertions, 45 deletions

diff --git a/games-simulation/crashtest/crashtest-1.1-r1.ebuild b/games-simulation/crashtest/crashtest-1.1-r1.ebuild
deleted file mode 100644
index 1faed8379238..000000000000
--- a/games-simulation/crashtest/crashtest-1.1-r1.ebuild
+++ /dev/null
@@ -1,45 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit eutils flag-o-matic
-
-DESCRIPTION="Educational car crash simulator"
-HOMEPAGE="http://www.stolk.org/crashtest/"
-SRC_URI="http://www.stolk.org/crashtest/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND="
-	dev-games/ode
-	media-libs/alsa-lib
-	media-libs/freeglut
-	x11-libs/fltk:1[opengl]
-	virtual/opengl
-	virtual/glu"
-DEPEND="${RDEPEND}
-	>=media-libs/plib-1.8.4"
-
-S=${WORKDIR}/${P}/src-${PN}
-
-PATCHES=(
-	"${FILESDIR}/${P}"-gentoo.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i \
-		-e "s:@GENTOO_DATADIR@:/usr/share/${PN}:" \
-		-e "s:@GENTOO_BINDIR@:/usr/bin:" \
-		Makefile ${PN}.cxx || die
-	append-cppflags -DHAVE_ISNANF
-}
-
-src_install() {
-	default
-	make_desktop_entry ${PN} Crashtest
-}
diff --git a/games-simulation/crashtest/crashtest-1.1-r2.ebuild b/games-simulation/crashtest/crashtest-1.1-r2.ebuild
new file mode 100644
index 000000000000..ff27796a7f4c
--- /dev/null
+++ b/games-simulation/crashtest/crashtest-1.1-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Educational car crash simulator"
+HOMEPAGE="http://www.stolk.org/crashtest/"
+SRC_URI="http://www.stolk.org/crashtest/${P}.tar.gz"
+S="${WORKDIR}/${P}/src-${PN}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-games/ode:=
+	media-libs/freeglut
+	media-libs/plib
+	virtual/glu
+	virtual/opengl
+	x11-libs/fltk:1[opengl]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e "s|@GENTOO_DATADIR@|${EPREFIX}/usr/share/${PN}|" \
+		-e "s|@GENTOO_BINDIR@|${EPREFIX}/usr/bin|" \
+		-i Makefile ${PN}.cxx || die
+
+	tc-export CXX
+}
+
+src_install() {
+	default
+
+	make_desktop_entry ${PN} Crashtest applications-games
+}