summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAustin English <wizardedit@gentoo.org>2016-09-22 12:59:57 -0500
committerAustin English <wizardedit@gentoo.org>2016-09-22 14:27:56 -0500
commit6427012a1b36047ba632b12620ece0dafc83150e (patch)
treec502f6eaff066cbd5c80ba9c60b6b655a7c51f19 /games-sports
parentnet-analyzer/flowgrind: Depend on sys-apps/util-linux by Christian Samsel (bu... (diff)
downloadgentoo-6427012a1b36047ba632b12620ece0dafc83150e.tar.gz
gentoo-6427012a1b36047ba632b12620ece0dafc83150e.tar.bz2
gentoo-6427012a1b36047ba632b12620ece0dafc83150e.zip
games-sports/billardgl: remove deprecated games eclass
Also update to EAPI 6 Gentoo-Bug: https://bugs.gentoo.org/574082 Package-Manager: portage-2.3.0
Diffstat (limited to 'games-sports')
-rw-r--r--games-sports/billardgl/billardgl-1.75-r2.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/games-sports/billardgl/billardgl-1.75-r2.ebuild b/games-sports/billardgl/billardgl-1.75-r2.ebuild
new file mode 100644
index 00000000000..f896f975bce
--- /dev/null
+++ b/games-sports/billardgl/billardgl-1.75-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="an OpenGL billards game"
+HOMEPAGE="http://www.billardgl.de/"
+SRC_URI="mirror://sourceforge/${PN}/BillardGL-${PV}.tar.gz
+ mirror://gentoo/${PN}.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="
+ media-libs/freeglut
+ x11-libs/libXi
+ x11-libs/libXmu
+ virtual/opengl
+ virtual/glu"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/BillardGL-${PV}/src
+
+src_prepare() {
+ default
+ sed -i \
+ -e "s:/usr/share/BillardGL/:/usr/share/${PN}/:" \
+ Namen.h \
+ || die "sed Namen.h failed"
+ sed -i \
+ -e '/^LINK/s:g++:$(CXX):' \
+ -e '/^CXX[[:space:]]/d' \
+ -e '/^CC[[:space:]]/d' \
+ -e '/^CXXFLAGS/s:=.*\(-D.*\)-.*:+=\1:' \
+ -e "/^LFLAGS/s:=:=${LDFLAGS}:" \
+ Makefile \
+ || die "sed Makefile failed"
+ sed -i \
+ -e 's:<iostream.h>:<iostream>:' \
+ -e 's:<fstream.h>:<fstream>\nusing namespace std;:' \
+ bmp.cpp \
+ || die "sed bmp.cpp failed"
+}
+
+src_install() {
+ newbin BillardGL ${PN}
+ insinto /usr/share/${PN}
+ doins -r lang Texturen
+ dodoc README
+ doicon "${DISTDIR}"/${PN}.png
+ make_desktop_entry ${PN} BillardGL
+}