games-util/grfcodec: update EAPI 7 -> 8

Bug: https://bugs.gentoo.org/715910
Bug: https://bugs.gentoo.org/859310
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/games-util/grfcodec/grfcodec-6.0.6_p20210310-r1.ebuild b/games-util/grfcodec/grfcodec-6.0.6_p20210310-r1.ebuild
new file mode 100644
index 000000000000..90d01d7a6794
--- /dev/null
+++ b/games-util/grfcodec/grfcodec-6.0.6_p20210310-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vcs-snapshot
+
+COMMIT=045774dee7cab1a618a3e0d9b39bff78a12b6efa
+
+DESCRIPTION="A suite of programs to modify openttd/Transport Tycoon Deluxe's GRF files"
+HOMEPAGE="https://github.com/OpenTTD/grfcodec"
+SRC_URI="https://github.com/OpenTTD/grfcodec/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="media-libs/libpng:="
+DEPEND="${RDEPEND}
+	dev-libs/boost"
+
+PATCHES=( "${FILESDIR}"/${PV} )
+
+src_configure() {
+	local mycmakeargs=(
+		# Make sure we don't use git by accident.
+		# Build system does not care much if it's
+		# executed successfully and populates
+		# YEARS / VERSION with empty values.
+		-DGIT_EXECUTABLE=/bin/do-not-use-git-executable
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/{grfcodec,grfid,grfstrip,nforenum}
+	doman docs/*.1
+	dodoc changelog.txt docs/*.txt
+}